Regression (108135) isOpaque() returns uninitialized variable.
[WebKit-https.git] / Source / tests.pri
1 # -------------------------------------------------------------------
2 # Project file for QtWebKit API unit-tests
3 #
4 # See 'Tools/qmake/README' for an overview of the build system
5 # -------------------------------------------------------------------
6
7 TEMPLATE = subdirs
8 CONFIG += ordered
9
10 WEBKIT_TESTS_DIR = $$PWD/WebKit/qt/tests
11
12 SUBDIRS += \
13     $$WEBKIT_TESTS_DIR/qwebframe \
14     $$WEBKIT_TESTS_DIR/qwebpage \
15     $$WEBKIT_TESTS_DIR/qwebelement \
16     $$WEBKIT_TESTS_DIR/qgraphicswebview \
17     $$WEBKIT_TESTS_DIR/qwebhistoryinterface \
18     $$WEBKIT_TESTS_DIR/qwebview \
19     $$WEBKIT_TESTS_DIR/qwebhistory \
20     $$WEBKIT_TESTS_DIR/qwebinspector \
21     $$WEBKIT_TESTS_DIR/hybridPixmap
22
23 linux-* {
24     # This test bypasses the library and links the tested code's object itself.
25     # This stresses the build system in some corners so we only run it on linux.
26     SUBDIRS += $$WEBKIT_TESTS_DIR/MIMESniffing
27 }
28
29 contains(QT_CONFIG, declarative)|contains(QT_CONFIG, qtquick1) {
30     SUBDIRS += $$WEBKIT_TESTS_DIR/qdeclarativewebview
31 }
32
33 # Benchmarks
34 SUBDIRS += \
35     $$WEBKIT_TESTS_DIR/benchmarks/painting \
36     $$WEBKIT_TESTS_DIR/benchmarks/loading
37
38 contains(DEFINES, ENABLE_WEBGL=1) {
39     SUBDIRS += $$WEBKIT_TESTS_DIR/benchmarks/webgl
40 }
41
42 !no_webkit2 {
43     WEBKIT2_TESTS_DIR = $$PWD/WebKit2/UIProcess/API/qt/tests
44
45     SUBDIRS += \
46         $$WEBKIT2_TESTS_DIR/publicapi \
47         $$WEBKIT2_TESTS_DIR/qquickwebview \
48         $$WEBKIT2_TESTS_DIR/qmltests
49 }