Tests failure on Chromium Mac after r130821.
[WebKit-https.git] / Source / tests.pri
1 # -------------------------------------------------------------------
2 # Project file for QtWebKit API unit-tests
3 #
4 # See 'Tools/qmake/README' for an overview of the build system
5 # -------------------------------------------------------------------
6
7 TEMPLATE = subdirs
8 CONFIG += ordered
9
10 WEBKIT_TESTS_DIR = $$PWD/WebKit/qt/tests
11
12 SUBDIRS += \
13     $$WEBKIT_TESTS_DIR/qobjectbridge \
14     $$WEBKIT_TESTS_DIR/qwebframe \
15     $$WEBKIT_TESTS_DIR/qwebpage \
16     $$WEBKIT_TESTS_DIR/qwebelement \
17     $$WEBKIT_TESTS_DIR/qgraphicswebview \
18     $$WEBKIT_TESTS_DIR/qwebhistoryinterface \
19     $$WEBKIT_TESTS_DIR/qwebview \
20     $$WEBKIT_TESTS_DIR/qwebhistory \
21     $$WEBKIT_TESTS_DIR/qwebinspector \
22     $$WEBKIT_TESTS_DIR/hybridPixmap
23
24 linux-* {
25     # This test bypasses the library and links the tested code's object itself.
26     # This stresses the build system in some corners so we only run it on linux.
27     SUBDIRS += $$WEBKIT_TESTS_DIR/MIMESniffing
28 }
29
30 # Benchmarks
31 SUBDIRS += \
32     $$WEBKIT_TESTS_DIR/benchmarks/painting \
33     $$WEBKIT_TESTS_DIR/benchmarks/loading
34
35 # WebGL performance tests are disabled temporarily.
36 # https://bugs.webkit.org/show_bug.cgi?id=80503
37 #
38 #enable?(WEBGL) {
39 #    SUBDIRS += $$WEBKIT_TESTS_DIR/benchmarks/webgl
40 #}
41
42 build?(webkit2): {
43     WEBKIT2_TESTS_DIR = $$PWD/WebKit2/UIProcess/API/qt/tests
44
45     have?(QTQUICK):SUBDIRS += \
46         $$WEBKIT2_TESTS_DIR/inspectorserver \
47         $$WEBKIT2_TESTS_DIR/publicapi \
48         $$WEBKIT2_TESTS_DIR/qquickwebview \
49         $$WEBKIT2_TESTS_DIR/qmltests
50
51     SUBDIRS += \
52         $$WEBKIT2_TESTS_DIR/qrawwebview
53 }