fa73cea7e4c59cb15a9984b6482ac3db75db033a
[WebKit-https.git] / Source / cmake / OptionsGTK.cmake
1 include(GNUInstallDirs)
2 include(VersioningUtils)
3
4 SET_PROJECT_VERSION(2 25 0)
5 set(WEBKITGTK_API_VERSION 4.0)
6
7 CALCULATE_LIBRARY_VERSIONS_FROM_LIBTOOL_TRIPLE(WEBKIT 75 0 38)
8 CALCULATE_LIBRARY_VERSIONS_FROM_LIBTOOL_TRIPLE(JAVASCRIPTCORE 32 0 14)
9
10 # These are shared variables, but we special case their definition so that we can use the
11 # CMAKE_INSTALL_* variables that are populated by the GNUInstallDirs macro.
12 set(LIB_INSTALL_DIR "${CMAKE_INSTALL_FULL_LIBDIR}" CACHE PATH "Absolute path to library installation directory")
13 set(EXEC_INSTALL_DIR "${CMAKE_INSTALL_FULL_BINDIR}" CACHE PATH "Absolute path to executable installation directory")
14 set(LIBEXEC_INSTALL_DIR "${CMAKE_INSTALL_FULL_LIBEXECDIR}/webkit2gtk-${WEBKITGTK_API_VERSION}" CACHE PATH "Absolute path to install executables executed by the library")
15
16 set(WEBKITGTK_HEADER_INSTALL_DIR "${CMAKE_INSTALL_INCLUDEDIR}/webkitgtk-${WEBKITGTK_API_VERSION}")
17 set(INTROSPECTION_INSTALL_GIRDIR "${CMAKE_INSTALL_FULL_DATADIR}/gir-1.0")
18 set(INTROSPECTION_INSTALL_TYPELIBDIR "${LIB_INSTALL_DIR}/girepository-1.0")
19
20 find_package(Cairo 1.10.2 REQUIRED)
21 find_package(Fontconfig 2.8.0 REQUIRED)
22 find_package(Freetype 2.4.2 REQUIRED)
23 find_package(LibGcrypt 1.6.0 REQUIRED)
24 find_package(GTK3 3.6.0 REQUIRED)
25 find_package(GDK3 3.6.0 REQUIRED)
26 find_package(HarfBuzz 0.9.2 REQUIRED)
27 find_package(ICU REQUIRED)
28 find_package(JPEG REQUIRED)
29 find_package(LibSoup 2.42.0 REQUIRED)
30 find_package(LibXml2 2.8.0 REQUIRED)
31 find_package(PNG REQUIRED)
32 find_package(Sqlite REQUIRED)
33 find_package(Threads REQUIRED)
34 find_package(ZLIB REQUIRED)
35 find_package(ATK REQUIRED)
36 find_package(WebP REQUIRED)
37 find_package(ATSPI 2.5.3)
38 find_package(EGL)
39 find_package(GTKUnixPrint)
40 find_package(OpenGL)
41 find_package(OpenGLES2)
42
43 WEBKIT_OPTION_BEGIN()
44
45 include(GStreamerDefinitions)
46
47 SET_AND_EXPOSE_TO_BUILD(USE_CAIRO TRUE)
48 SET_AND_EXPOSE_TO_BUILD(USE_XDGMIME TRUE)
49 SET_AND_EXPOSE_TO_BUILD(USE_GCRYPT TRUE)
50
51 if (WTF_CPU_ARM OR WTF_CPU_MIPS)
52     SET_AND_EXPOSE_TO_BUILD(USE_CAPSTONE ${DEVELOPER_MODE})
53 endif ()
54
55 # For old versions of HarfBuzz that do not expose an API for the OpenType MATH
56 # table, we enable our own code to parse that table.
57 if ("${PC_HARFBUZZ_VERSION}" VERSION_LESS "1.3.3")
58     add_definitions(-DENABLE_OPENTYPE_MATH=1)
59 endif ()
60
61 # Set the default value for ENABLE_GLES2 automatically.
62 # We are not enabling or disabling automatically a feature here, because
63 # the feature is by default always on (ENABLE_OPENGL=ON).
64 # What we select here automatically is if we use OPENGL (ENABLE_GLES2=OFF)
65 # or OPENGLES2 (ENABLE_GLES2=ON) for building the feature.
66 set(ENABLE_GLES2_DEFAULT OFF)
67
68 if (NOT OPENGL_FOUND AND OPENGLES2_FOUND)
69     set(ENABLE_GLES2_DEFAULT ON)
70 endif ()
71
72 # Public options specific to the GTK+ port. Do not add any options here unless
73 # there is a strong reason we should support changing the value of the option,
74 # and the option is not relevant to any other WebKit ports.
75 WEBKIT_OPTION_DEFINE(ENABLE_GLES2 "Whether to enable OpenGL ES 2.0." PUBLIC ${ENABLE_GLES2_DEFAULT})
76 WEBKIT_OPTION_DEFINE(ENABLE_GTKDOC "Whether or not to use generate gtkdoc." PUBLIC OFF)
77 WEBKIT_OPTION_DEFINE(ENABLE_INTROSPECTION "Whether to enable GObject introspection." PUBLIC ON)
78 WEBKIT_OPTION_DEFINE(ENABLE_OPENGL "Whether to use OpenGL." PUBLIC ON)
79 WEBKIT_OPTION_DEFINE(ENABLE_PLUGIN_PROCESS_GTK2 "Whether to build WebKitPluginProcess2 to load GTK2 based plugins." PUBLIC ON)
80 WEBKIT_OPTION_DEFINE(ENABLE_QUARTZ_TARGET "Whether to enable support for the Quartz windowing target." PUBLIC ${GTK3_SUPPORTS_QUARTZ})
81 WEBKIT_OPTION_DEFINE(ENABLE_X11_TARGET "Whether to enable support for the X11 windowing target." PUBLIC ${GTK3_SUPPORTS_X11})
82 WEBKIT_OPTION_DEFINE(ENABLE_WAYLAND_TARGET "Whether to enable support for the Wayland windowing target." PUBLIC ${GTK3_SUPPORTS_WAYLAND})
83 WEBKIT_OPTION_DEFINE(USE_LIBNOTIFY "Whether to enable the default web notification implementation." PUBLIC ON)
84 WEBKIT_OPTION_DEFINE(USE_LIBHYPHEN "Whether to enable the default automatic hyphenation implementation." PUBLIC ON)
85 WEBKIT_OPTION_DEFINE(USE_LIBSECRET "Whether to enable the persistent credential storage using libsecret." PUBLIC ON)
86 WEBKIT_OPTION_DEFINE(USE_OPENJPEG "Whether to enable support for JPEG2000 images." PUBLIC ON)
87 WEBKIT_OPTION_DEFINE(USE_WOFF2 "Whether to enable support for WOFF2 Web Fonts." PUBLIC ON)
88
89 # Private options specific to the GTK+ port. Changing these options is
90 # completely unsupported. They are intended for use only by WebKit developers.
91 WEBKIT_OPTION_DEFINE(USE_REDIRECTED_XCOMPOSITE_WINDOW "Whether to use a Redirected XComposite Window for accelerated compositing in X11." PRIVATE ON)
92 WEBKIT_OPTION_DEFINE(USE_OPENVR "Whether to use OpenVR as WebVR backend." PRIVATE ${ENABLE_EXPERIMENTAL_FEATURES})
93
94 # FIXME: Can we use cairo-glesv2 to avoid this conflict?
95 WEBKIT_OPTION_CONFLICT(ENABLE_ACCELERATED_2D_CANVAS ENABLE_GLES2)
96
97 WEBKIT_OPTION_DEPEND(ENABLE_3D_TRANSFORMS ENABLE_OPENGL)
98 WEBKIT_OPTION_DEPEND(ENABLE_ACCELERATED_2D_CANVAS ENABLE_OPENGL)
99 WEBKIT_OPTION_DEPEND(ENABLE_ASYNC_SCROLLING ENABLE_OPENGL)
100 WEBKIT_OPTION_DEPEND(ENABLE_GLES2 ENABLE_OPENGL)
101 WEBKIT_OPTION_DEPEND(ENABLE_PLUGIN_PROCESS_GTK2 ENABLE_X11_TARGET)
102 WEBKIT_OPTION_DEPEND(ENABLE_WEBGL ENABLE_OPENGL)
103 WEBKIT_OPTION_DEPEND(USE_REDIRECTED_XCOMPOSITE_WINDOW ENABLE_OPENGL)
104 WEBKIT_OPTION_DEPEND(USE_REDIRECTED_XCOMPOSITE_WINDOW ENABLE_X11_TARGET)
105
106 SET_AND_EXPOSE_TO_BUILD(ENABLE_DEVELOPER_MODE ${DEVELOPER_MODE})
107 if (DEVELOPER_MODE)
108     WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_MINIBROWSER PUBLIC ON)
109     WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_API_TESTS PRIVATE ON)
110 else ()
111     WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_MINIBROWSER PUBLIC OFF)
112     WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_API_TESTS PRIVATE OFF)
113 endif ()
114
115 if (CMAKE_SYSTEM_NAME MATCHES "Linux")
116     WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_MEMORY_SAMPLER PRIVATE ON)
117     WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_RESOURCE_USAGE PRIVATE ON)
118 else ()
119     WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_MEMORY_SAMPLER PRIVATE OFF)
120     WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_RESOURCE_USAGE PRIVATE OFF)
121 endif ()
122
123 if (CMAKE_SYSTEM_NAME MATCHES "Linux" AND NOT EXISTS "/.flatpak-info")
124     WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_BUBBLEWRAP_SANDBOX PUBLIC ON)
125 else ()
126     WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_BUBBLEWRAP_SANDBOX PRIVATE OFF)
127 endif ()
128
129 # Enable variation fonts when cairo >= 1.16, fontconfig >= 2.13.0, freetype >= 2.9.0 and harfbuzz >= 1.4.2.
130 if (("${PC_CAIRO_VERSION}" VERSION_GREATER "1.16.0" OR "${PC_CAIRO_VERSION}" STREQUAL "1.16.0")
131     AND ("${PC_FONTCONFIG_VERSION}" VERSION_GREATER "2.13.0" OR "${PC_FONTCONFIG_VERSION}" STREQUAL "2.13.0")
132     AND ("${FREETYPE_VERSION_STRING}" VERSION_GREATER "2.9.0" OR "${FREETYPE_VERSION_STRING}" STREQUAL "2.9.0")
133     AND ("${PC_HARFBUZZ_VERSION}" VERSION_GREATER "1.4.2" OR "${PC_HARFBUZZ_VERSION}" STREQUAL "1.4.2"))
134     WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_VARIATION_FONTS PRIVATE ON)
135 endif ()
136
137 # Public options shared with other WebKit ports. Do not add any options here
138 # without approval from a GTK+ reviewer. There must be strong reason to support
139 # changing the value of the option.
140 WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_ACCELERATED_2D_CANVAS PUBLIC OFF)
141 WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_ASYNC_SCROLLING PRIVATE ON)
142 WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_DRAG_SUPPORT PUBLIC ON)
143 WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_GEOLOCATION PUBLIC ON)
144 WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_ICONDATABASE PUBLIC ON)
145 WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_SPELLCHECK PUBLIC ON)
146 WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_TOUCH_EVENTS PUBLIC ON)
147 WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_WEB_CRYPTO PUBLIC ON)
148 WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_WEBDRIVER PUBLIC ON)
149
150 # Private options shared with other WebKit ports. Add options here when
151 # we need a value different from the default defined in WebKitFeatures.cmake.
152 # Changing these options is completely unsupported.
153 WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_CONTENT_EXTENSIONS PRIVATE ON)
154 WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_DOWNLOAD_ATTRIBUTE PRIVATE ON)
155 WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_ENCRYPTED_MEDIA PRIVATE ${ENABLE_EXPERIMENTAL_FEATURES})
156 WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_FTPDIR PRIVATE OFF)
157 WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_INPUT_TYPE_COLOR PRIVATE ON)
158 WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_MEDIA_STREAM PRIVATE ${ENABLE_EXPERIMENTAL_FEATURES})
159 WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_MHTML PRIVATE ON)
160 WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_SERVICE_WORKER PRIVATE ${ENABLE_EXPERIMENTAL_FEATURES})
161 WEBKIT_OPTION_DEFAULT_PORT_VALUE(ENABLE_WEB_RTC PRIVATE ${ENABLE_EXPERIMENTAL_FEATURES})
162
163 include(GStreamerDependencies)
164
165 # Finalize the value for all options. Do not attempt to use an option before
166 # this point, and do not attempt to change any option after this point.
167 WEBKIT_OPTION_END()
168
169 SET_AND_EXPOSE_TO_BUILD(WTF_PLATFORM_QUARTZ ${ENABLE_QUARTZ_TARGET})
170 SET_AND_EXPOSE_TO_BUILD(WTF_PLATFORM_X11 ${ENABLE_X11_TARGET})
171 SET_AND_EXPOSE_TO_BUILD(WTF_PLATFORM_WAYLAND ${ENABLE_WAYLAND_TARGET})
172
173 if (ENABLE_NETSCAPE_PLUGIN_API)
174     # MOZ_X11 and XP_UNIX are required by npapi.h. Their value is not checked;
175     # only their definedness is. They should only be defined in the true case.
176     if (ENABLE_X11_TARGET)
177         SET_AND_EXPOSE_TO_BUILD(MOZ_X11 1)
178     endif ()
179     SET_AND_EXPOSE_TO_BUILD(XP_UNIX 1)
180 endif ()
181
182 set(ENABLE_PLUGIN_PROCESS ${ENABLE_NETSCAPE_PLUGIN_API})
183
184 add_definitions(-DBUILDING_GTK__=1)
185 add_definitions(-DGETTEXT_PACKAGE="WebKit2GTK-${WEBKITGTK_API_VERSION}")
186 add_definitions(-DWEBKITGTK_API_VERSION_STRING="${WEBKITGTK_API_VERSION}")
187 add_definitions(-DJSC_GLIB_API_ENABLED)
188
189 set(GTK_LIBRARIES ${GTK3_LIBRARIES})
190 set(GTK_INCLUDE_DIRS ${GTK3_INCLUDE_DIRS})
191 set(GDK_LIBRARIES ${GDK3_LIBRARIES})
192 set(GDK_INCLUDE_DIRS ${GDK3_INCLUDE_DIRS})
193
194 SET_AND_EXPOSE_TO_BUILD(HAVE_GTK_GESTURES ${GTK3_SUPPORTS_GESTURES})
195 SET_AND_EXPOSE_TO_BUILD(HAVE_GTK_UNIX_PRINTING ${GTKUnixPrint_FOUND})
196
197 set(glib_components gio gio-unix gobject gthread gmodule)
198 find_package(GLIB 2.36 REQUIRED COMPONENTS ${glib_components})
199
200 if (ENABLE_XSLT)
201     find_package(LibXslt 1.1.7 REQUIRED)
202 endif ()
203
204 if (ENABLE_ACCELERATED_2D_CANVAS)
205     if (GLX_FOUND)
206         list(APPEND CAIROGL_COMPONENTS cairo-glx)
207     endif ()
208     if (EGL_FOUND)
209         list(APPEND CAIROGL_COMPONENTS cairo-egl)
210     endif ()
211
212     find_package(CairoGL 1.10.2 COMPONENTS ${CAIROGL_COMPONENTS})
213     if (NOT CAIROGL_FOUND)
214         message(FATAL_ERROR "CairoGL is needed for ENABLE_ACCELERATED_2D_CANVAS")
215     endif ()
216 endif ()
217
218 if (ENABLE_BUBBLEWRAP_SANDBOX)
219     find_program(BWRAP_EXECUTABLE bwrap)
220     if (NOT BWRAP_EXECUTABLE)
221         message(FATAL_ERROR "bwrap executable is needed for ENABLE_BUBBLEWRAP_SANDBOX")
222     endif ()
223     add_definitions(-DBWRAP_EXECUTABLE="${BWRAP_EXECUTABLE}")
224
225     execute_process(
226         COMMAND "${BWRAP_EXECUTABLE}" --version
227         RESULT_VARIABLE BWRAP_RET
228         OUTPUT_VARIABLE BWRAP_OUTPUT
229     )
230     if (BWRAP_RET)
231         message(FATAL_ERROR "Failed to run ${BWRAP_EXECUTABLE}")
232     endif ()
233     string(REGEX MATCH "([0-9]+.[0-9]+.[0-9]+)" BWRAP_VERSION "${BWRAP_OUTPUT}")
234     if (NOT "${BWRAP_VERSION}" VERSION_GREATER_EQUAL "0.3.1")
235         message(FATAL_ERROR "bwrap must be >= 0.3.1 but ${BWRAP_VERSION} found")
236     endif ()
237
238     find_package(Libseccomp)
239     if (NOT LIBSECCOMP_FOUND)
240         message(FATAL_ERROR "libseccomp is needed for ENABLE_BUBBLEWRAP_SANDBOX")
241     endif ()
242
243     find_program(DBUS_PROXY_EXECUTABLE xdg-dbus-proxy)
244     if (NOT DBUS_PROXY_EXECUTABLE)
245         message(FATAL_ERROR "xdg-dbus-proxy not found and is needed for ENABLE_BUBBLEWRAP_SANDBOX")
246     endif ()
247     add_definitions(-DDBUS_PROXY_EXECUTABLE="${DBUS_PROXY_EXECUTABLE}")
248 endif ()
249
250 if (USE_LIBSECRET)
251     find_package(Libsecret)
252     if (NOT LIBSECRET_FOUND)
253         message(FATAL_ERROR "libsecret is needed for USE_LIBSECRET")
254     endif ()
255 endif ()
256
257 if (ENABLE_GEOLOCATION)
258     find_package(GeoClue2 2.1.5)
259     if (NOT GEOCLUE2_FOUND)
260         message(FATAL_ERROR "Geoclue is needed for ENABLE_GEOLOCATION.")
261     endif ()
262 endif ()
263
264 if (ENABLE_INTROSPECTION)
265     find_package(GObjectIntrospection)
266     if (NOT INTROSPECTION_FOUND)
267         message(FATAL_ERROR "GObjectIntrospection is needed for ENABLE_INTROSPECTION.")
268     endif ()
269 endif ()
270
271 if (ENABLE_WEB_CRYPTO)
272     find_package(Libtasn1 REQUIRED)
273     if (NOT LIBTASN1_FOUND)
274         message(FATAL_ERROR "libtasn1 is required to enable Web Crypto API support.")
275     endif ()
276     if (LIBGCRYPT_VERSION VERSION_LESS 1.7.0)
277         message(FATAL_ERROR "libgcrypt 1.7.0 is required to enable Web Crypto API support.")
278     endif ()
279 endif ()
280
281 if (ENABLE_WEBDRIVER)
282     # WebDriver requires newer versions of GLib and Soup.
283     if (PC_GLIB_VERSION VERSION_LESS "2.40")
284         message(FATAL_ERROR "GLib 2.40 is required to enable WebDriver support.")
285     endif ()
286     if (PC_LIBSOUP_VERSION VERSION_LESS "2.48")
287         message(FATAL_ERROR "libsoup 2.48 is required to enable WebDriver support.")
288     endif ()
289 endif ()
290
291 SET_AND_EXPOSE_TO_BUILD(USE_TEXTURE_MAPPER TRUE)
292
293 if (ENABLE_OPENGL)
294     # ENABLE_OPENGL is true if either USE_OPENGL or ENABLE_GLES2 is true.
295     # But USE_OPENGL is the opposite of ENABLE_GLES2.
296     if (ENABLE_GLES2)
297         find_package(OpenGLES2 REQUIRED)
298         SET_AND_EXPOSE_TO_BUILD(USE_OPENGL_ES TRUE)
299
300         if (NOT EGL_FOUND)
301             message(FATAL_ERROR "EGL is needed for ENABLE_GLES2.")
302         endif ()
303     else ()
304         if (NOT OPENGL_FOUND)
305             message(FATAL_ERROR "Either OpenGL or OpenGLES2 is needed for ENABLE_OPENGL.")
306         endif ()
307         SET_AND_EXPOSE_TO_BUILD(USE_OPENGL TRUE)
308     endif ()
309
310     if (NOT EGL_FOUND AND (NOT ENABLE_X11_TARGET OR NOT GLX_FOUND))
311         message(FATAL_ERROR "Either GLX or EGL is needed for ENABLE_OPENGL.")
312     endif ()
313
314     SET_AND_EXPOSE_TO_BUILD(ENABLE_GRAPHICS_CONTEXT_3D TRUE)
315
316     SET_AND_EXPOSE_TO_BUILD(USE_TEXTURE_MAPPER_GL TRUE)
317
318     SET_AND_EXPOSE_TO_BUILD(USE_EGL ${EGL_FOUND})
319
320     if (ENABLE_X11_TARGET AND GLX_FOUND AND USE_OPENGL)
321         SET_AND_EXPOSE_TO_BUILD(USE_GLX TRUE)
322     endif ()
323
324     SET_AND_EXPOSE_TO_BUILD(USE_COORDINATED_GRAPHICS TRUE)
325     SET_AND_EXPOSE_TO_BUILD(USE_NICOSIA TRUE)
326 endif ()
327
328 if (ENABLE_PLUGIN_PROCESS_GTK2)
329     find_package(GTK2 2.24.10 REQUIRED)
330     find_package(GDK2 2.24.10 REQUIRED)
331 endif ()
332
333 if (ENABLE_SPELLCHECK)
334     find_package(Enchant)
335     if (NOT PC_ENCHANT_FOUND)
336         message(FATAL_ERROR "Enchant is needed for ENABLE_SPELLCHECK")
337     endif ()
338 endif ()
339
340 if (ENABLE_QUARTZ_TARGET)
341     if (NOT GTK3_SUPPORTS_QUARTZ)
342         message(FATAL_ERROR "Recompile GTK+ with Quartz backend to use ENABLE_QUARTZ_TARGET")
343     endif ()
344 endif ()
345
346 if (ENABLE_X11_TARGET)
347     if (NOT GTK3_SUPPORTS_X11)
348         message(FATAL_ERROR "Recompile GTK+ with X11 backend to use ENABLE_X11_TARGET")
349     endif ()
350
351     find_package(X11 REQUIRED)
352     if (NOT X11_Xcomposite_FOUND)
353         message(FATAL_ERROR "libXcomposite is required for ENABLE_X11_TARGET")
354     elseif (NOT X11_Xdamage_FOUND)
355         message(FATAL_ERROR "libXdamage is required for ENABLE_X11_TARGET")
356     elseif (NOT X11_Xrender_FOUND)
357         message(FATAL_ERROR "libXrender is required for ENABLE_X11_TARGET")
358     elseif (NOT X11_Xt_FOUND)
359         message(FATAL_ERROR "libXt is required for ENABLE_X11_TARGET")
360     endif ()
361 endif ()
362
363 if (ENABLE_WAYLAND_TARGET)
364     if (NOT GTK3_SUPPORTS_WAYLAND)
365         message(FATAL_ERROR "Recompile GTK+ with Wayland backend to use ENABLE_WAYLAND_TARGET")
366     endif ()
367
368     if (GTK3_VERSION VERSION_LESS 3.12)
369         message(FATAL_ERROR "GTK+ 3.12 is required to use ENABLE_WAYLAND_TARGET")
370     endif ()
371
372     if (NOT EGL_FOUND)
373         message(FATAL_ERROR "EGL is required to use ENABLE_WAYLAND_TARGET")
374     endif ()
375
376     find_package(Wayland REQUIRED)
377 endif ()
378
379 if (USE_LIBNOTIFY)
380     find_package(LibNotify)
381     if (NOT LIBNOTIFY_FOUND)
382        message(FATAL_ERROR "libnotify is needed for USE_LIBNOTIFY.")
383     endif ()
384 endif ()
385
386 if (USE_LIBHYPHEN)
387     find_package(Hyphen)
388     if (NOT HYPHEN_FOUND)
389        message(FATAL_ERROR "libhyphen is needed for USE_LIBHYPHEN.")
390     endif ()
391 endif ()
392
393 if (USE_OPENJPEG)
394     find_package(OpenJPEG)
395     if (NOT OpenJPEG_FOUND)
396         message(FATAL_ERROR "libopenjpeg is needed for USE_OPENJPEG.")
397     endif ()
398     if ("${OPENJPEG_MAJOR_VERSION}.${OPENJPEG_MINOR_VERSION}.${OPENJPEG_BUILD_VERSION}" VERSION_LESS "2.2.0")
399         message(FATAL_ERROR "libopenjpeg 2.2.0 is required for USE_OPENJPEG.")
400     endif ()
401 endif ()
402
403 if (USE_WOFF2)
404     find_package(WOFF2Dec 1.0.2)
405     if (NOT WOFF2DEC_FOUND)
406        message(FATAL_ERROR "libwoff2dec is needed for USE_WOFF2.")
407     endif ()
408 endif ()
409
410 # https://bugs.webkit.org/show_bug.cgi?id=182247
411 if (ENABLED_COMPILER_SANITIZERS)
412     set(ENABLE_INTROSPECTION OFF)
413 endif ()
414
415 # Override the cached variables, gtk-doc and gobject-introspection do not really work when cross-building.
416 if (CMAKE_CROSSCOMPILING)
417     set(ENABLE_GTKDOC OFF)
418     set(ENABLE_INTROSPECTION OFF)
419 endif ()
420
421 # Override the cached variable, gtk-doc does not really work when building on Mac.
422 if (APPLE)
423     set(ENABLE_GTKDOC OFF)
424 endif ()
425
426 set(DERIVED_SOURCES_WEBKITGTK_DIR ${DERIVED_SOURCES_DIR}/webkitgtk)
427 set(DERIVED_SOURCES_WEBKITGTK_API_DIR ${DERIVED_SOURCES_WEBKITGTK_DIR}/webkit)
428 set(DERIVED_SOURCES_WEBKIT2GTK_DIR ${DERIVED_SOURCES_DIR}/webkit2gtk)
429 set(DERIVED_SOURCES_WEBKIT2GTK_API_DIR ${DERIVED_SOURCES_WEBKIT2GTK_DIR}/webkit2)
430 set(DERIVED_SOURCES_JAVASCRIPCOREGTK_DIR ${DERIVED_SOURCES_JAVASCRIPTCORE_DIR}/javascriptcoregtk)
431 set(DERIVED_SOURCES_JAVASCRIPCORE_GLIB_API_DIR ${DERIVED_SOURCES_JAVASCRIPTCORE_DIR}/javascriptcoregtk/jsc)
432 set(FORWARDING_HEADERS_WEBKIT2GTK_DIR ${FORWARDING_HEADERS_DIR}/webkit2gtk)
433 set(FORWARDING_HEADERS_WEBKIT2GTK_EXTENSION_DIR ${FORWARDING_HEADERS_DIR}/webkit2gtk-webextension)
434
435 set(JavaScriptCore_PKGCONFIG_FILE ${CMAKE_BINARY_DIR}/Source/JavaScriptCore/javascriptcoregtk-${WEBKITGTK_API_VERSION}.pc)
436 set(WebKit2_PKGCONFIG_FILE ${CMAKE_BINARY_DIR}/Source/WebKit/webkit2gtk-${WEBKITGTK_API_VERSION}.pc)
437 set(WebKit2WebExtension_PKGCONFIG_FILE ${CMAKE_BINARY_DIR}/Source/WebKit/webkit2gtk-web-extension-${WEBKITGTK_API_VERSION}.pc)
438
439 set(JavaScriptCore_LIBRARY_TYPE SHARED)
440 set(SHOULD_INSTALL_JS_SHELL ON)
441
442 # Add a typelib file to the list of all typelib dependencies. This makes it easy to
443 # expose a 'gir' target with all gobject-introspection files.
444 macro(ADD_TYPELIB typelib)
445     if (ENABLE_INTROSPECTION)
446         get_filename_component(target_name ${typelib} NAME_WE)
447         add_custom_target(${target_name}-gir ALL DEPENDS ${typelib})
448         list(APPEND GObjectIntrospectionTargets ${target_name}-gir)
449         set(GObjectIntrospectionTargets ${GObjectIntrospectionTargets} PARENT_SCOPE)
450     endif ()
451 endmacro()
452
453 # CMake does not automatically add --whole-archive when building shared objects from
454 # a list of convenience libraries. This can lead to missing symbols in the final output.
455 # We add --whole-archive to all libraries manually to prevent the linker from trimming
456 # symbols that we actually need later. With ld64 on darwin, we use -all_load instead.
457 macro(ADD_WHOLE_ARCHIVE_TO_LIBRARIES _list_name)
458     if (CMAKE_SYSTEM_NAME MATCHES "Darwin")
459         list(APPEND ${_list_name} -Wl,-all_load)
460     else ()
461         set(_tmp)
462         foreach (item IN LISTS ${_list_name})
463             if ("${item}" STREQUAL "PRIVATE" OR "${item}" STREQUAL "PUBLIC")
464                 list(APPEND _tmp "${item}")
465             else ()
466                 list(APPEND _tmp -Wl,--whole-archive "${item}" -Wl,--no-whole-archive)
467             endif ()
468         endforeach ()
469         set(${_list_name} ${_tmp})
470     endif ()
471 endmacro()
472
473 include(GStreamerChecks)