2011-02-21 Pavel Feldman <pfeldman@chromium.org>
[WebKit-https.git] / Source / autotools / webkit.m4
1 dnl macros to check for JavaScriptCore and WebKit/Gtk+ dependencies
2 dnl
3 dnl The rationale is so that we can share these macros between 
4 dnl WebKit and JavaScriptCore builds.
5
6 # global states
7 m4_define([initialized], [no])
8
9 AC_DEFUN([INIT_C_CXX_FLAGS],
10 [dnl
11 # If CXXFLAGS and CFLAGS are unset, default to empty.
12 # This is to tell automake not to include '-g' if CXXFLAGS is not set
13 # For more info - http://www.gnu.org/software/automake/manual/autoconf.html#C_002b_002b-Compiler
14 if test -z "$CXXFLAGS"; then
15    CXXFLAGS=""
16 fi
17 if test -z "$CFLAGS"; then
18    CFLAGS=""
19 fi
20 ])
21
22 AC_DEFUN_ONCE([WEBKIT_INIT],
23 [dnl
24 dnl check if we have the required packages to have successful checks
25 dnl
26 # Make sure CXXFLAGS and CFLAGS are set before expanding AC_PROG_CXX to avoid
27 # building with '-g -O2' on Release builds.
28 AC_REQUIRE([INIT_C_CXX_FLAGS])
29
30 # check for -fvisibility=hidden compiler support (GCC >= 4)
31 saved_CFLAGS="$CFLAGS"
32 CFLAGS="$CFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
33 AC_MSG_CHECKING([if ${CXX} supports -fvisibility=hidden -fvisibility-inlines-hidden])
34 AC_COMPILE_IFELSE([char foo;],
35       [ AC_MSG_RESULT([yes])
36         SYMBOL_VISIBILITY="-fvisibility=hidden" SYMBOL_VISIBILITY_INLINES="-fvisibility-inlines-hidden" ],
37         AC_MSG_RESULT([no]))
38 CFLAGS="$saved_CFLAGS"
39 AC_SUBST(SYMBOL_VISIBILITY)
40 AC_SUBST(SYMBOL_VISIBILITY_INLINES)
41
42 # check for pkg-config
43 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
44 if test "$PKG_CONFIG" = "no"; then
45    AC_MSG_ERROR([Cannot find pkg-config, make sure it is installed in your PATH])
46 fi
47
48 AC_PATH_PROG(PERL, perl)
49 if test -z "$PERL"; then
50    AC_MSG_ERROR([You need 'perl' to compile WebKit])
51 fi
52
53 AC_PATH_PROG(PYTHON, python)
54 if test -z "$PYTHON"; then
55    AC_MSG_ERROR([You need 'python' to compile WebKit])
56 fi
57
58 AC_PATH_PROG(BISON, bison)
59 if test -z "$BISON"; then
60    AC_MSG_ERROR([You need the 'bison' parser generator to compile WebKit])
61 fi
62
63 AC_PATH_PROG(MV, mv)
64 if test -z "$MV"; then
65    AC_MSG_ERROR([You need 'mv' to compile WebKit])
66 fi
67
68 AC_REQUIRE([AC_PROG_CC])
69 AC_REQUIRE([AC_PROG_CXX])
70 AM_PROG_CC_STDC
71 AM_PROG_CC_C_O
72 AC_PROG_INSTALL
73 AC_SYS_LARGEFILE
74
75 # Check whether a C++ was found (AC_PROG_CXX sets $CXX to "g++" even when it
76 # doesn't exist)
77 AC_LANG_PUSH([C++])
78 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],[],[AC_MSG_ERROR([No C++ compiler found])])
79 AC_LANG_POP([C++])
80
81 # C/C++ Language Features
82 AC_C_CONST
83 AC_C_INLINE
84 AC_C_VOLATILE
85
86 # C/C++ Headers
87 AC_REQUIRE([AC_HEADER_STDC])
88 AC_HEADER_STDBOOL
89
90 m4_define([initialized], [yes])
91 ])
92
93 AC_DEFUN_ONCE([WEBKIT_CHECK_DEPENDENCIES],
94 [dnl
95 dnl check for module dependencies
96 for module in $1
97 do
98     case $module in
99         glib) _WEBKIT_CHECK_GLIB ;;
100         unicode) _WEBKIT_CHECK_UNICODE ;;
101         *) AC_MSG_ERROR([I don't support that module. Sorry..]) ;;
102
103     esac
104 done
105 ])
106
107 AC_DEFUN_ONCE([_WEBKIT_CHECK_GLIB],
108 [dnl
109 dnl check for glib
110 # Version requirements
111 GLIB_REQUIRED_VERSION=2.27.90
112 AM_PATH_GLIB_2_0($GLIB_REQUIRED_VERSION)
113 if test -z "$GLIB_GENMARSHAL" || test -z "$GLIB_MKENUMS"; then
114    AC_MSG_ERROR([You need the GLib dev tools in your path])
115 fi
116 GLIB_GSETTINGS
117 ])
118
119 AC_DEFUN_ONCE([_WEBKIT_CHECK_UNICODE],
120 [dnl
121 dnl determine the Unicode backend
122 AC_MSG_CHECKING([which Unicode backend to use])
123 AC_ARG_WITH(unicode_backend,
124             AC_HELP_STRING([--with-unicode-backend=@<:@icu/glib@:>@],
125                            [Select Unicode backend (WARNING: the glib-based backend is slow, and incomplete) [default=icu]]),
126             [],[with_unicode_backend="icu"])
127
128 case "$with_unicode_backend" in
129      icu|glib) ;;
130      *) AC_MSG_ERROR([Invalid Unicode backend: must be icu or glib.]) ;;
131 esac
132
133 AC_MSG_RESULT([$with_unicode_backend])
134
135 if test "$with_unicode_backend" = "icu"; then
136         case "$host" in
137             *-*-darwin*)
138                 UNICODE_CFLAGS="-I$srcdir/Source/JavaScriptCore/icu -I$srcdir/Source/WebCore/icu"
139                 UNICODE_LIBS="-licucore"
140                 ;;
141             *-*-mingw*)
142                 UNICODE_CFLAGS=""
143                 UNICODE_LIBS="-licuin -licuuc"
144                 ;;
145             *)
146                 AC_PATH_PROG(icu_config, icu-config, no)
147                 if test "$icu_config" = "no"; then
148                         AC_MSG_ERROR([Cannot find icu-config. The ICU library is needed.])
149                 fi
150
151                 # We don't use --cflags as this gives us a lot of things that we don't
152                 # necessarily want, like debugging and optimization flags
153                 # See man (1) icu-config for more info.
154                 UNICODE_CFLAGS=`$icu_config --cppflags`
155                 UNICODE_LIBS=`$icu_config --ldflags-libsonly`
156                 ;;
157         esac
158 fi
159
160 if test "$with_unicode_backend" = "glib"; then
161         PKG_CHECK_MODULES([UNICODE], [glib-2.0 pango >= 1.21.0])
162 fi
163
164 AC_SUBST([UNICODE_CFLAGS])
165 AC_SUBST([UNICODE_LIBS])
166 ])