Text Autosizing: Multiply large fonts less, as they are already more legible.
[WebKit-https.git] / Source / api.pri
1 # -------------------------------------------------------------------
2 # Project file for the QtWebKit C++ APIs
3 #
4 # See 'Tools/qmake/README' for an overview of the build system
5 # -------------------------------------------------------------------
6
7 TEMPLATE = lib
8 TARGET = QtWebKit
9
10 WEBKIT_DESTDIR = $${ROOT_BUILD_DIR}/lib
11
12 # Use Qt5's module system
13 load(qt_build_config)
14 MODULE = webkit
15 MODULE_PRI = ../Tools/qmake/qt_webkit.pri
16
17 # ---------------- Custom developer-build handling -------------------
18 #
19 # The assumption for Qt developer builds is that the module file
20 # will be put into qtbase/mkspecs/modules, and the libraries into
21 # qtbase/lib, with rpath/install_name set to the Qt lib dir.
22 #
23 # For WebKit we don't want that behavior for the libraries, as we want
24 # them to be self-contained in the WebKit build dir.
25 #
26 CONFIG += force_independent
27
28 BASE_TARGET = $$TARGET
29
30 load(qt_module_config)
31
32 # Make sure the module config doesn't override our preferred build config.
33 debug_and_release:if(!debug|!release) {
34     # Removing debug_and_release causes issues with lib suffixes when building debug on Windows.
35     # Work around it by only removing build_all, and still create the Makefiles for both configurations.
36     win32*: CONFIG -= build_all
37     else: CONFIG -= debug_and_release
38 }
39
40 # Allow doing a debug-only build of WebKit (not supported by Qt)
41 macx:!debug_and_release:debug: TARGET = $$BASE_TARGET
42
43 # Make sure the install_name of the QtWebKit library point to webkit
44 macx {
45     # We do our own absolute path so that we can trick qmake into
46     # using the webkit build path instead of the Qt install path.
47     CONFIG -= absolute_library_soname
48     QMAKE_LFLAGS_SONAME = $$QMAKE_LFLAGS_SONAME$$WEBKIT_DESTDIR/
49
50     !debug_and_release|build_pass {
51         # We also have to make sure the install_name is correct when
52         # the library is installed.
53         change_install_name.depends = install_target
54
55         # The install rules generated by qmake for frameworks are busted in
56         # that both the debug and the release makefile copy QtWebKit.framework
57         # into the install dir, so whatever changes we did to the release library
58         # will get overwritten when the debug library is installed. We work around
59         # that by running install_name on both, for both configs.
60         change_install_name.commands = framework_dir=\$\$(dirname $(TARGETD)); \
61             for file in \$\$(ls $$[QT_INSTALL_LIBS]/\$\$framework_dir/$$BASE_TARGET*); do \
62                 install_name_tool -id \$\$file \$\$file; \
63             done
64         default_install_target.target = install
65         default_install_target.depends += change_install_name
66
67         QMAKE_EXTRA_TARGETS += change_install_name default_install_target
68     }
69 }
70
71 WEBKIT += wtf
72
73 WEBKIT += javascriptcore
74
75 WEBKIT += webcore
76
77 !no_webkit2 {
78     WEBKIT += webkit2
79
80     # Ensure that changes to the WebKit1 and WebKit2 API will trigger a qmake of this
81     # file, which in turn runs syncqt to update the forwarding headers.
82     QMAKE_INTERNAL_INCLUDED_FILES *= WebKit2/Target.pri
83     QMAKE_INTERNAL_INCLUDED_FILES *= WebKit/WebKit1.pro
84 }
85
86 !no_webkit1: WEBKIT += webkit1
87
88 qnx {
89     # see: https://bugs.webkit.org/show_bug.cgi?id=93460
90     # the gcc 4.4.2 used in the qnx bbndk cannot cope with
91     # the linkage step of libQtWebKit, adding a dummy .cpp
92     # file fixes this though - so do this here
93     dummyfile.target = dummy.cpp
94     dummyfile.commands = touch $$dummyfile.target
95     QMAKE_EXTRA_TARGETS += dummyfile
96     GENERATED_SOURCES += $$dummyfile.target
97 }