[Qt] [WK2] Expose web view classes to QML
[WebKit-https.git] / Source / WebKit2 / UIProcess / API / qt / qmlplugin / qmlplugin.pro
1 TEMPLATE = lib
2 TARGET = webkit2qmlplugin
3 TARGETPATH = QtWebKit/experimental
4 CONFIG += qt plugin
5
6 SOURCES += plugin.cpp
7
8 include(../../../../../WebKit.pri)
9 QT += declarative
10
11 QMAKE_RPATHDIR = $$OUTPUT_DIR/lib $$QMAKE_RPATHDIR
12
13
14 # From WK1 qml module. Copies the qmldir file to the build directory,
15 # so we can use it in place without installing.
16 QMLDIRFILE = $${_PRO_FILE_PWD_}/qmldir
17 copy2build.input = QMLDIRFILE
18 CONFIG(QTDIR_build) {
19     copy2build.output = $$QT_BUILD_TREE/imports/$$TARGETPATH/qmldir
20 } else {
21     copy2build.output = $$OUTPUT_DIR/imports/$$TARGETPATH/qmldir
22 }
23 !contains(TEMPLATE_PREFIX, vc):copy2build.variable_out = PRE_TARGETDEPS
24 copy2build.commands = $$QMAKE_COPY ${QMAKE_FILE_IN} ${QMAKE_FILE_OUT}
25 copy2build.name = COPY ${QMAKE_FILE_IN}
26 copy2build.CONFIG += no_link
27 QMAKE_EXTRA_COMPILERS += copy2build
28
29
30 CONFIG(QTDIR_build) {
31     DESTDIR = $$QT_BUILD_TREE/imports/$$TARGETPATH
32 } else {
33     DESTDIR = $$OUTPUT_DIR/imports/$$TARGETPATH
34 }
35 target.path = $$[QT_INSTALL_IMPORTS]/$$TARGETPATH
36
37 qmldir.files += $$PWD/qmldir
38 qmldir.path +=  $$[QT_INSTALL_IMPORTS]/$$TARGETPATH
39
40 INSTALLS += target qmldir