[Qt] Make it possible to build WebKit without QtWidgets
[WebKit-https.git] / Source / WebKit / WebKit1.pri
1 # -------------------------------------------------------------------
2 # This file contains shared rules used both when building WebKit1
3 # itself, and by targets that use WebKit1.
4 #
5 # See 'Tools/qmake/README' for an overview of the build system
6 # -------------------------------------------------------------------
7
8 SOURCE_DIR = $${ROOT_WEBKIT_DIR}/Source/WebKit
9
10 INCLUDEPATH += \
11     $$SOURCE_DIR/qt/Api \
12     $$SOURCE_DIR/qt/WebCoreSupport \
13     $$ROOT_WEBKIT_DIR/Source/WTF/wtf/qt
14
15 contains(DEFINES, ENABLE_VIDEO=1):contains(DEFINES, WTF_USE_QTKIT=1) {
16     LIBS += -framework Security -framework IOKit
17
18     # We can know the Mac OS version by using the Darwin major version
19     DARWIN_VERSION = $$split(QMAKE_HOST.version, ".")
20     DARWIN_MAJOR_VERSION = $$first(DARWIN_VERSION)
21     equals(DARWIN_MAJOR_VERSION, "11") {
22         LIBS += $${ROOT_WEBKIT_DIR}/WebKitLibraries/libWebKitSystemInterfaceLion.a
23     } else:equals(DARWIN_MAJOR_VERSION, "10") {
24         LIBS += $${ROOT_WEBKIT_DIR}/WebKitLibraries/libWebKitSystemInterfaceSnowLeopard.a
25     } else:equals(DARWIN_MAJOR_VERSION, "9") {
26         LIBS += $${ROOT_WEBKIT_DIR}/WebKitLibraries/libWebKitSystemInterfaceLeopard.a
27     }
28 }
29
30 contains(DEFINES, ENABLE_DEVICE_ORIENTATION=1) || contains(DEFINES, ENABLE_ORIENTATION_EVENTS=1) {
31     haveQt(5) {
32         QT += sensors
33     } else {
34         CONFIG *= mobility
35         MOBILITY *= sensors
36     }
37 }
38
39 contains(DEFINES, ENABLE_GEOLOCATION=1):haveQt(5): QT += location
40
41 contains(CONFIG, texmap): DEFINES += WTF_USE_TEXTURE_MAPPER=1
42
43 plugin_backend_xlib: PKGCONFIG += x11
44
45 QT += network
46 haveQt(5): QT += widgets printsupport quick
47
48 contains(DEFINES, WTF_USE_TEXTURE_MAPPER_GL=1)|contains(DEFINES, ENABLE_WEBGL=1) {
49     QT *= opengl
50     # Make sure OpenGL libs are after the webcore lib so MinGW can resolve symbols
51     win32*:!win32-msvc*: LIBS += $$QMAKE_LIBS_OPENGL
52 }
53
54