[Qt] Fix build against Qt5 after refactor of widgets out of QtGUi
[WebKit-https.git] / Source / WebKit.pro
1 TEMPLATE = subdirs
2 CONFIG += ordered
3
4 include(WebKit.pri)
5
6 !v8 {
7     exists($$PWD/JavaScriptCore/JavaScriptCore.pro): SUBDIRS += JavaScriptCore/JavaScriptCore.pro
8     exists($$PWD/JavaScriptCore/jsc.pro): SUBDIRS += JavaScriptCore/jsc.pro
9 }
10
11 webkit2 {
12     lessThan(QT_MAJOR_VERSION, 5) {
13         message("Building WebKit2 with Qt versions older than 5.0 is no longer supported.")
14         message("Read http://www.mail-archive.com/webkit-qt@lists.webkit.org/msg01674.html for more information.")
15         error("Aborting build.")
16     }
17     exists($$PWD/WebKit2/WebKit2.pro): SUBDIRS += WebKit2/WebKit2.pro
18 }
19
20 greaterThan(QT_MAJOR_VERSION, 4) {
21     isEmpty(QT.widgets.name)|isEmpty(QT.printsupport.name) {
22         message("Building WebKit against Qt 5.0 requires the QtWidgets and QtPrintSupport modules.")
23         error("Aborting build.")
24     }
25 }
26
27 SUBDIRS += WebCore
28 SUBDIRS += WebKit/qt/QtWebKit.pro
29
30 webkit2 {
31     exists($$PWD/WebKit2/WebProcess.pro): SUBDIRS += WebKit2/WebProcess.pro
32     exists($$PWD/WebKit2/UIProcess/API/qt/tests): SUBDIRS += WebKit2/UIProcess/API/qt/tests
33     SUBDIRS += WebKit2/UIProcess/API/qt/qmlplugin
34 }
35
36 exists($$PWD/WebKit/qt/declarative) {
37     lessThan(QT_MAJOR_VERSION, 5) {
38         contains(QT_CONFIG, declarative): SUBDIRS += WebKit/qt/declarative
39     } else {
40         contains(QT_CONFIG, qtquick1): SUBDIRS += WebKit/qt/declarative
41     }
42 }
43
44 exists($$PWD/WebKit/qt/tests): SUBDIRS += WebKit/qt/tests
45
46 build-qtscript {
47     SUBDIRS += \
48         JavaScriptCore/qt/api/QtScript.pro \
49         JavaScriptCore/qt/tests \
50         JavaScriptCore/qt/benchmarks
51 }
52
53 symbian {
54     exists($$PWD/WebKit/qt/symbian/platformplugin): SUBDIRS += WebKit/qt/symbian/platformplugin
55
56     # Forward the install target to WebCore. A workaround since INSTALLS is not implemented for symbian
57     install.commands = $(MAKE) -C WebCore install
58     QMAKE_EXTRA_TARGETS += install
59 }
60
61 include(WebKit/qt/docs/docs.pri)