2011-02-23 Patrick Gansterer <paroga@webkit.org>
[WebKit-https.git] / Source / WebKit.pro
1 TEMPLATE = subdirs
2 CONFIG += ordered
3
4 include(WebKit.pri)
5
6 !v8 {
7     exists($$PWD/JavaScriptCore/JavaScriptCore.pro): SUBDIRS += JavaScriptCore/JavaScriptCore.pro
8     exists($$PWD/JavaScriptCore/jsc.pro): SUBDIRS += JavaScriptCore/jsc.pro
9 }
10
11 webkit2:exists($$PWD/WebKit2/WebKit2.pro): SUBDIRS += WebKit2/WebKit2.pro
12
13 SUBDIRS += WebCore
14 SUBDIRS += WebKit/qt/QtWebKit.pro
15
16 webkit2:exists($$PWD/WebKit2/WebProcess.pro): SUBDIRS += WebKit2/WebProcess.pro
17
18 contains(QT_CONFIG, declarative) {
19     exists($$PWD/WebKit/qt/declarative): SUBDIRS += WebKit/qt/declarative
20 }
21
22 exists($$PWD/WebKit/qt/tests): SUBDIRS += WebKit/qt/tests
23
24 build-qtscript {
25     SUBDIRS += \
26         JavaScriptCore/qt/api/QtScript.pro \
27         JavaScriptCore/qt/tests \
28         JavaScriptCore/qt/benchmarks
29 }
30
31 symbian {
32     # Forward the install target to WebCore. A workaround since INSTALLS is not implemented for symbian
33     install.commands = $(MAKE) -C WebCore install
34     QMAKE_EXTRA_TARGETS += install
35 }
36
37 include(WebKit/qt/docs/docs.pri)