2011-02-23 Patrick Gansterer <paroga@webkit.org>
[WebKit-https.git] / Source / WebKit.pri
1 # Include file to make it easy to include WebKit into Qt projects
2
3 # Detect that we are building as a standalone package by the presence of
4 # either the generated files directory or as part of the Qt package through
5 # QTDIR_build
6 CONFIG(QTDIR_build): CONFIG += standalone_package
7 else:exists($$PWD/WebCore/generated): CONFIG += standalone_package
8
9 CONFIG += depend_includepath
10 DEPENDPATH += $$OUT_PWD
11
12 DEFINES += BUILDING_QT__=1
13 building-libs {
14     win32-msvc*|win32-icc: INCLUDEPATH += $$PWD/JavaScriptCore/os-win32
15 } else {
16     CONFIG(QTDIR_build) {
17         QT += webkit
18     } else {
19         QMAKE_LIBDIR = $$OUTPUT_DIR/lib $$QMAKE_LIBDIR
20         QTWEBKITLIBNAME = QtWebKit
21         mac:!static:contains(QT_CONFIG, qt_framework):!CONFIG(webkit_no_framework) {
22             LIBS += -framework $$QTWEBKITLIBNAME
23             QMAKE_FRAMEWORKPATH = $$OUTPUT_DIR/lib $$QMAKE_FRAMEWORKPATH
24         } else {
25             build_pass: win32-*|wince* {
26                 !CONFIG(release, debug|release): QTWEBKITLIBNAME = $${QTWEBKITLIBNAME}d
27                 QTWEBKITLIBNAME = $${QTWEBKITLIBNAME}$${QT_MAJOR_VERSION}
28                 win32-g++*: LIBS += -l$$QTWEBKITLIBNAME
29                 else: LIBS += $${QTWEBKITLIBNAME}.lib
30             } else {
31                 LIBS += -lQtWebKit
32                 symbian {
33                     TARGET.EPOCSTACKSIZE = 0x14000 // 80 kB
34                     # For EXEs only: set heap to usable value
35                     TARGET.EPOCHEAPSIZE =
36                     heapSizeRule = \
37                     "$${LITERAL_HASH}ifdef WINSCW" \
38                         "EPOCHEAPSIZE  0x40000 0x2000000 // Min 256kB, Max 32MB" \
39                     "$${LITERAL_HASH}else" \
40                         "EPOCHEAPSIZE  0x40000 0x10000000 // Min 256kB, Max 256MB" \
41                     "$${LITERAL_HASH}endif"
42                     MMP_RULES += heapSizeRule
43                 }
44             }
45         }
46     }
47     DEPENDPATH += $$PWD/WebKit/qt/Api
48 }
49
50 CONFIG(release, debug|release) {
51     DEFINES += NDEBUG
52 }
53
54 INCLUDEPATH += \
55     $$OUTPUT_DIR/include/QtWebKit \
56     $$OUTPUT_DIR/include
57 INCLUDEPATH += $$QT.script.includes
58
59 CONFIG -= warn_on
60 *-g++*:QMAKE_CXXFLAGS += -Wall -Wextra -Wreturn-type -fno-strict-aliasing -Wcast-align -Wchar-subscripts -Wformat-security -Wreturn-type -Wno-unused-parameter -Wno-sign-compare -Wno-switch -Wno-switch-enum -Wundef -Wmissing-noreturn -Winit-self
61
62 # Treat warnings as errors on x86/Linux/GCC
63 linux-g++* {
64     isEqual(QT_ARCH,x86_64)|isEqual(QT_ARCH,i386): QMAKE_CXXFLAGS += -Werror
65 }
66
67 symbian|*-armcc {
68     # Enable GNU compiler extensions to the ARM compiler for all Qt ports using RVCT
69     RVCT_COMMON_CFLAGS = --gnu --diag_suppress 68,111,177,368,830,1293
70     RVCT_COMMON_CXXFLAGS = $$RVCT_COMMON_CFLAGS --no_parse_templates
71     # Make debug symbols leaner in RVCT4.x. Ignored by compiler for release builds
72     QMAKE_CXXFLAGS.ARMCC_4_0 += --remove_unneeded_entities
73 }
74
75 *-armcc {
76     QMAKE_CFLAGS += $$RVCT_COMMON_CFLAGS
77     QMAKE_CXXFLAGS += $$RVCT_COMMON_CXXFLAGS
78 }
79
80 symbian {
81     QMAKE_CXXFLAGS.ARMCC += $$RVCT_COMMON_CXXFLAGS
82 }
83
84 valgrind {
85     contains(JAVASCRIPTCORE_JIT,yes): error("'JAVASCRIPTCORE_JIT=yes' not supported with valgrind")
86     QMAKE_CXXFLAGS += -g
87     QMAKE_LFLAGS += -g
88     DEFINES += USE_SYSTEM_MALLOC=1
89     DEFINES += ENABLE_JIT=0
90     JAVASCRIPTCORE_JIT = no
91 }
92
93 ##### Defaults for some mobile platforms
94 symbian|maemo5|maemo6 {
95     CONFIG += disable_uitools
96     CONFIG += enable_fast_mobile_scrolling
97     CONFIG += use_qt_mobile_theme
98     maemo6: CONFIG += include_webinspector
99 } else {
100     CONFIG += include_webinspector
101 }
102
103 ####
104
105 contains(QT_CONFIG, modular):!contains(QT_CONFIG, uitools)|disable_uitools: DEFINES *= QT_NO_UITOOLS
106
107 !contains(QT_CONFIG, modular) {
108     $$QT.phonon.includes = $QMAKE_INCDIR_QT/phonon
109     $$QT.phonon.libs = $$QMAKE_LIBDIR_QT
110 }
111
112 # Disable a few warnings on Windows. The warnings are also
113 # disabled in WebKitLibraries/win/tools/vsprops/common.vsprops
114 win32-msvc*|wince*: QMAKE_CXXFLAGS += -wd4291 -wd4344 -wd4396 -wd4503 -wd4800 -wd4819 -wd4996
115
116 CONFIG(qt_minimal) {
117     DEFINES *= QT_NO_ANIMATION
118     DEFINES *= QT_NO_BEARERMANAGEMENT
119     DEFINES *= QT_NO_CLIPBOARD
120     DEFINES *= QT_NO_COMBOBOX
121     DEFINES *= QT_NO_CONCURRENT
122     DEFINES *= QT_NO_CRASHHANDLER
123     DEFINES *= QT_NO_CURSOR
124     DEFINES *= QT_NO_DESKTOPSERVICES
125     DEFINES *= QT_NO_FILEDIALOG
126     DEFINES *= QT_NO_GRAPHICSEFFECT
127     DEFINES *= QT_NO_IM
128     DEFINES *= QT_NO_INPUTDIALOG
129     DEFINES *= QT_NO_LINEEDIT
130     DEFINES *= QT_NO_MESSAGEBOX
131     DEFINES *= QT_NO_OPENSSL
132     DEFINES *= QT_NO_PRINTER
133     DEFINES *= QT_NO_QUUID_STRING
134     DEFINES *= QT_NO_SHORTCUT
135     DEFINES *= QT_NO_STYLE_STYLESHEET
136     DEFINES *= QT_NO_SYSTEMTRAYICON
137     DEFINES *= QT_NO_TEMPORARYFILE
138     DEFINES *= QT_NO_TOOLTIP
139     DEFINES *= QT_NO_UITOOLS
140     DEFINES *= QT_NO_UNDOCOMMAND
141     DEFINES *= QT_NO_UNDOSTACK
142     DEFINES *= QT_NO_XRENDER
143 }
144
145 contains(DEFINES, QT_NO_UITOOLS): CONFIG -= uitools