[chromium] Update win/linux pixel expectations for r90701 (part 12/12).
[WebKit-https.git] / Source / WebKit.pri
1 # Include file to make it easy to include WebKit into Qt projects
2
3 contains(QT_CONFIG, qpa)|contains(QT_CONFIG, embedded): CONFIG += embedded
4
5 # Detect that we are building as a standalone package by the presence of
6 # either the generated files directory or as part of the Qt package through
7 # QTDIR_build
8 CONFIG(QTDIR_build) {
9     CONFIG += standalone_package
10     # Make sure we compile both debug and release on mac when inside Qt.
11     # This line was extracted from qbase.pri instead of including the whole file
12     win32|mac:!macx-xcode:CONFIG += debug_and_release
13 } else {
14     !CONFIG(release, debug|release) {
15         OBJECTS_DIR = obj/debug
16     } else { # Release
17         OBJECTS_DIR = obj/release
18         DEFINES *= NDEBUG
19     }
20     exists($$PWD/WebCore/generated):CONFIG += standalone_package
21     # Make sure that build_all follows the build_all config in WebCore
22     mac:contains(QT_CONFIG, qt_framework):!CONFIG(webkit_no_framework):!build_pass:CONFIG += build_all
23 }
24
25 CONFIG(standalone_package): DEFINES *= NDEBUG
26
27 CONFIG += depend_includepath
28 DEPENDPATH += $$OUT_PWD
29
30 DEFINES += BUILDING_QT__=1
31 building-libs {
32     win32-msvc*|win32-icc: INCLUDEPATH += $$PWD/JavaScriptCore/os-win32
33 } else {
34     CONFIG(QTDIR_build) {
35         QT += webkit
36     } else {
37         QMAKE_LIBDIR = $$OUTPUT_DIR/lib $$QMAKE_LIBDIR
38         QTWEBKITLIBNAME = QtWebKit
39         mac:!static:contains(QT_CONFIG, qt_framework):!CONFIG(webkit_no_framework) {
40             LIBS += -framework $$QTWEBKITLIBNAME
41             QMAKE_FRAMEWORKPATH = $$OUTPUT_DIR/lib $$QMAKE_FRAMEWORKPATH
42         } else {
43             build_pass: win32-*|wince* {
44                 !CONFIG(release, debug|release): QTWEBKITLIBNAME = $${QTWEBKITLIBNAME}d
45                 QTWEBKITLIBNAME = $${QTWEBKITLIBNAME}$${QT_MAJOR_VERSION}
46                 win32-g++*: LIBS += -l$$QTWEBKITLIBNAME
47                 else: LIBS += $${QTWEBKITLIBNAME}.lib
48             } else {
49                 LIBS += -lQtWebKit
50                 symbian {
51                     TARGET.EPOCSTACKSIZE = 0x14000 // 80 kB
52                     # For EXEs only: set heap to usable value
53                     TARGET.EPOCHEAPSIZE =
54                     heapSizeRule = \
55                     "$${LITERAL_HASH}ifdef WINSCW" \
56                         "EPOCHEAPSIZE  0x40000 0x2000000 // Min 256kB, Max 32MB" \
57                     "$${LITERAL_HASH}else" \
58                         "EPOCHEAPSIZE  0x40000 0x10000000 // Min 256kB, Max 256MB" \
59                     "$${LITERAL_HASH}endif"
60                     MMP_RULES += heapSizeRule
61                 }
62             }
63         }
64     }
65     DEPENDPATH += $$PWD/WebKit/qt/Api
66 }
67
68 CONFIG(release, debug|release) {
69     DEFINES += NDEBUG
70 }
71
72 INCLUDEPATH += \
73     $$PWD \
74     $$OUTPUT_DIR/include/QtWebKit \
75     $$OUTPUT_DIR/include \
76     $$QT.script.includes
77
78 DEFINES += QT_ASCII_CAST_WARNINGS
79
80 webkit2:INCLUDEPATH *= $$OUTPUT_DIR/include/WebKit2
81
82 # Pick up 3rdparty libraries from INCLUDE/LIB just like with MSVC
83 win32-g++* {
84     TMPPATH            = $$quote($$(INCLUDE))
85     QMAKE_INCDIR_POST += $$split(TMPPATH,";")
86     TMPPATH            = $$quote($$(LIB))
87     QMAKE_LIBDIR_POST += $$split(TMPPATH,";")
88 }
89
90 CONFIG -= warn_on
91 *-g++*:QMAKE_CXXFLAGS += -Wall -Wextra -Wreturn-type -fno-strict-aliasing -Wchar-subscripts -Wformat-security -Wreturn-type -Wno-unused-parameter -Wno-sign-compare -Wno-switch -Wno-switch-enum -Wundef -Wmissing-noreturn -Winit-self
92
93 # Treat warnings as errors on x86/Linux/GCC
94 linux-g++* {
95     isEqual(QT_ARCH,x86_64)|isEqual(QT_ARCH,i386): QMAKE_CXXFLAGS += -Werror
96
97     greaterThan(QT_GCC_MAJOR_VERSION, 3):greaterThan(QT_GCC_MINOR_VERSION, 5) {
98         if (!contains(QMAKE_CXXFLAGS, -std=c++0x) && !contains(QMAKE_CXXFLAGS, -std=gnu++0x)) {
99             # We need to deactivate those warnings because some names conflicts with upcoming c++0x types (e.g.nullptr).
100             QMAKE_CFLAGS_WARN_ON += -Wno-c++0x-compat
101             QMAKE_CXXFLAGS_WARN_ON += -Wno-c++0x-compat
102             QMAKE_CFLAGS += -Wno-c++0x-compat
103             QMAKE_CXXFLAGS += -Wno-c++0x-compat
104         }
105     }
106 }
107
108 symbian|*-armcc {
109     # Enable GNU compiler extensions to the ARM compiler for all Qt ports using RVCT
110     RVCT_COMMON_CFLAGS = --gnu --diag_suppress 68,111,177,368,830,1293
111     RVCT_COMMON_CXXFLAGS = $$RVCT_COMMON_CFLAGS --no_parse_templates
112     # Make debug symbols leaner in RVCT4.x. Ignored by compiler for release builds
113     QMAKE_CXXFLAGS.ARMCC_4_0 += --remove_unneeded_entities
114     # Match other compilers' (GCC, MSVC, WINSCW...) behavior regarding bitfield signedness.
115     # This flag is not needed for RVCT 2.x.
116     QMAKE_CXXFLAGS.ARMCC_4_0 += --signed_bitfields
117 }
118
119 *-armcc {
120     QMAKE_CFLAGS += $$RVCT_COMMON_CFLAGS
121     QMAKE_CXXFLAGS += $$RVCT_COMMON_CXXFLAGS
122 }
123
124 symbian {
125     QMAKE_CXXFLAGS.ARMCC += $$RVCT_COMMON_CXXFLAGS
126 }
127
128 valgrind {
129     contains(JAVASCRIPTCORE_JIT,yes): error("'JAVASCRIPTCORE_JIT=yes' not supported with valgrind")
130     QMAKE_CXXFLAGS += -g
131     QMAKE_LFLAGS += -g
132     DEFINES += USE_SYSTEM_MALLOC=1
133     DEFINES += ENABLE_JIT=0
134     JAVASCRIPTCORE_JIT = no
135 }
136
137 # Disable dependency to a specific version of a Qt package for non-production builds
138 symbian:!CONFIG(production):default_deployment.pkg_prerules -= pkg_depends_qt
139
140 ##### Defaults for some mobile platforms
141 symbian|maemo5|maemo6 {
142     CONFIG += disable_uitools
143     CONFIG += enable_fast_mobile_scrolling
144     CONFIG += use_qt_mobile_theme
145     maemo6: CONFIG += include_webinspector
146 } else {
147     CONFIG += include_webinspector
148 }
149
150 *sh4* {
151     CONFIG += disable_uitools
152 }
153 ####
154
155 disable_uitools: DEFINES *= QT_NO_UITOOLS
156
157 # Disable a few warnings on Windows. The warnings are also
158 # disabled in WebKitLibraries/win/tools/vsprops/common.vsprops
159 win32-msvc*|wince*: QMAKE_CXXFLAGS += -wd4291 -wd4344 -wd4396 -wd4503 -wd4800 -wd4819 -wd4996
160
161 CONFIG(qt_minimal) {
162     DEFINES *= QT_NO_ANIMATION
163     DEFINES *= QT_NO_BEARERMANAGEMENT
164     DEFINES *= QT_NO_CLIPBOARD
165     DEFINES *= QT_NO_COMBOBOX
166     DEFINES *= QT_NO_CONCURRENT
167     DEFINES *= QT_NO_CRASHHANDLER
168     DEFINES *= QT_NO_CURSOR
169     DEFINES *= QT_NO_DESKTOPSERVICES
170     DEFINES *= QT_NO_FILEDIALOG
171     DEFINES *= QT_NO_GRAPHICSEFFECT
172     DEFINES *= QT_NO_IM
173     DEFINES *= QT_NO_INPUTDIALOG
174     DEFINES *= QT_NO_LINEEDIT
175     DEFINES *= QT_NO_MESSAGEBOX
176     DEFINES *= QT_NO_OPENSSL
177     DEFINES *= QT_NO_PRINTER
178     DEFINES *= QT_NO_QUUID_STRING
179     DEFINES *= QT_NO_SHORTCUT
180     DEFINES *= QT_NO_STYLE_STYLESHEET
181     DEFINES *= QT_NO_SYSTEMTRAYICON
182     DEFINES *= QT_NO_TEMPORARYFILE
183     DEFINES *= QT_NO_TOOLTIP
184     DEFINES *= QT_NO_UITOOLS
185     DEFINES *= QT_NO_UNDOCOMMAND
186     DEFINES *= QT_NO_UNDOSTACK
187     DEFINES *= QT_NO_XRENDER
188 }
189
190 contains(DEFINES, QT_NO_UITOOLS): CONFIG -= uitools