ee65da4aff40f93ef7e02fcd75e0a4f019face58
[WebKit-https.git] / Source / WebCore / bindings / scripts / preprocessor.pm
1 #
2 # Copyright (C) 2005 Nikolas Zimmermann <wildfox@kde.org>
3 # Copyright (C) 2011 Google Inc.
4 #
5 # This library is free software; you can redistribute it and/or
6 # modify it under the terms of the GNU Library General Public
7 # License as published by the Free Software Foundation; either
8 # version 2 of the License, or (at your option) any later version.
9 #
10 # This library is distributed in the hope that it will be useful,
11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
13 # Library General Public License for more details.
14 #
15 # You should have received a copy of the GNU Library General Public License
16 # along with this library; see the file COPYING.LIB.  If not, write to
17 # the Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
18 # Boston, MA 02110-1301, USA.
19 #
20
21 use strict;
22 use warnings;
23
24 use Config;
25 use IPC::Open2;
26 use IPC::Open3;
27 use Text::ParseWords;
28
29 BEGIN {
30    use Exporter   ();
31    our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
32    $VERSION     = 1.00;
33    @ISA         = qw(Exporter);
34    @EXPORT      = qw(&applyPreprocessor);
35    %EXPORT_TAGS = ( );
36    @EXPORT_OK   = ();
37 }
38
39 # Returns an array of lines.
40 sub applyPreprocessor
41 {
42     my $fileName = shift;
43     my $defines = shift;
44     my $preprocessor = shift;
45
46     my @args = ();
47     if (!$preprocessor) {
48         require Config;
49         if ($ENV{CC}) {
50             $preprocessor = $ENV{CC};
51         } elsif (-x "/usr/bin/clang") {
52             $preprocessor = "/usr/bin/clang";
53         } else {
54             $preprocessor = "/usr/bin/gcc";
55         }
56         if ($Config::Config{"osname"} eq "MSWin32") {
57             push(@args, qw(/EP));
58         } else {
59             push(@args, qw(-E -P -x c++));
60         }
61     }
62
63     if ($Config::Config{"osname"} eq "darwin") {
64         push(@args, "-I" . $ENV{BUILT_PRODUCTS_DIR} . "/usr/local/include") if $ENV{BUILT_PRODUCTS_DIR};
65         push(@args, "-isysroot", $ENV{SDKROOT}) if $ENV{SDKROOT};
66     }
67
68     # Remove double quotations from $defines and extract macros.
69     # For example, if $defines is ' "A=1" "B=1" C=1 ""    D  ',
70     # then it is converted into four macros -DA=1, -DB=1, -DC=1 and -DD.
71     $defines =~ s/\"//g;
72     my @macros = grep { $_ } split(/\s+/, $defines); # grep skips empty macros.
73     @macros = map { "-D$_" } @macros;
74
75     my $pid = 0;
76     if ($Config{osname} eq "cygwin") {
77         $ENV{PATH} = "$ENV{PATH}:/cygdrive/c/cygwin/bin";
78         my @preprocessorAndFlags;
79         if ($preprocessor eq "/usr/bin/gcc") {
80             @preprocessorAndFlags = split(' ', $preprocessor);
81         } else {        
82             $preprocessor =~ /"(.*)"/;
83             chomp(my $preprocessor = `cygpath -u '$1'`) if (defined $1);
84             chomp($fileName = `cygpath -w '$fileName'`);
85             @preprocessorAndFlags = ($preprocessor, "/nologo", "/EP");
86         }
87         # This call can fail if Windows rebases cygwin, so retry a few times until it succeeds.
88         for (my $tries = 0; !$pid && ($tries < 20); $tries++) {
89             eval {
90                 # Suppress STDERR so that if we're using cl.exe, the output
91                 # name isn't needlessly echoed.
92                 use Symbol 'gensym'; my $err = gensym;
93                 $pid = open3(\*PP_IN, \*PP_OUT, $err, @preprocessorAndFlags, @args, @macros, $fileName);
94                 1;
95             } or do {
96                 sleep 1;
97             }
98         };
99     } elsif ($Config::Config{"osname"} eq "MSWin32") {
100         # Suppress STDERR so that if we're using cl.exe, the output
101         # name isn't needlessly echoed.
102         use Symbol 'gensym'; my $err = gensym;
103         $pid = open3(\*PP_IN, \*PP_OUT, $err, $preprocessor, @args, @macros, $fileName);
104     } else {
105         $pid = open2(\*PP_OUT, \*PP_IN, shellwords($preprocessor), @args, @macros, $fileName);
106     }
107     close PP_IN;
108     my @documentContent = <PP_OUT>;
109     close PP_OUT;
110     waitpid($pid, 0);
111     return @documentContent;
112 }
113
114 1;