Tests failure on Chromium Mac after r130821.
[WebKit-https.git] / Source / QtWebKit.pro
1 # -------------------------------------------------------------------
2 # Root project file for QtWebKit
3 #
4 # See 'Tools/qmake/README' for an overview of the build system
5 # -------------------------------------------------------------------
6
7 TEMPLATE = subdirs
8 CONFIG += ordered
9
10 api.file = api.pri
11 SUBDIRS += api
12
13 build?(webkit2) {
14     webprocess.file = WebKit2/WebProcess.pro
15     SUBDIRS += webprocess
16     enable?(PLUGIN_PROCESS) {
17         pluginprocess.file = WebKit2/PluginProcess.pro
18         SUBDIRS += pluginprocess
19     }
20 }
21
22 include(WebKit/qt/docs/docs.pri)
23
24 declarative.file = WebKit/qt/declarative/declarative.pro
25 declarative.makefile = Makefile.declarative
26 have?(QTQUICK): SUBDIRS += declarative
27
28 build?(webkit1) {
29     build?(tests) {
30         tests.file = tests.pri
31         SUBDIRS += tests
32     }
33
34     examples.file = WebKit/qt/examples/examples.pro
35     examples.CONFIG += no_default_target
36     examples.makefile = Makefile
37     SUBDIRS += examples
38 }