[Qt] Replace use of QApplication with QGuiApplication
[WebKit-https.git] / Source / QtWebKit.pro
1 # -------------------------------------------------------------------
2 # Root project file for QtWebKit
3 #
4 # See 'Tools/qmake/README' for an overview of the build system
5 # -------------------------------------------------------------------
6
7 TEMPLATE = subdirs
8 CONFIG += ordered
9
10 api.file = api.pri
11 SUBDIRS += api
12
13 !no_webkit2 {
14     webprocess.file = WebKit2/WebProcess.pro
15     SUBDIRS += webprocess
16 }
17
18 include(WebKit/qt/docs/docs.pri)
19
20 SUBDIRS += WebKit/qt/declarative
21
22 tests.file = tests.pri
23 SUBDIRS += tests
24
25 examples.file = WebKit/qt/examples/examples.pro
26 examples.CONFIG += no_default_target
27 examples.makefile = Makefile
28 SUBDIRS += examples
29
30 !haveQt(5):!build_pass {
31     # Use our own copy of syncqt from Qt 4.8 to generate forwarding headers
32     syncqt = $$toSystemPath($${ROOT_WEBKIT_DIR}/Tools/qmake/syncqt-4.8)
33     command = $$syncqt
34     win32-msvc*: command = $$command -windows
35
36     outdir = $$toSystemPath($${ROOT_BUILD_DIR})
37     rootdir = $$toSystemPath($${ROOT_WEBKIT_DIR})
38
39     fwheader_generator.commands = perl $${command} -outdir $${outdir} -separate-module $${TARGET}$${DIRLIST_SEPARATOR}$${rootdir}$${DIRLIST_SEPARATOR}$$toSystemPath(Source/WebKit/qt/Api)
40     fwheader_generator.depends = $${syncqt}
41
42     variables = $$computeSubdirVariables(api)
43
44     api_qmake.target = $$eval($${variables}.target)-qmake_all
45     api_qmake.depends = fwheader_generator
46
47     api_makefile.target = $$eval($${variables}.makefile)
48     api_makefile.depends = fwheader_generator
49
50     QMAKE_EXTRA_TARGETS += fwheader_generator api_qmake api_makefile
51 }