initial commit
[WebKit-https.git] / Source / QtWebKit.pro
1 # -------------------------------------------------------------------
2 # Root project file for QtWebKit
3 #
4 # See 'Tools/qmake/README' for an overview of the build system
5 # -------------------------------------------------------------------
6
7 TEMPLATE = subdirs
8 CONFIG += ordered
9
10 api.file = api.pri
11 SUBDIRS += api
12
13 build?(webkit1) {
14     webkitwidgets.file = widgetsapi.pri
15     SUBDIRS += webkitwidgets
16 }
17
18 build?(webkit2) {
19     webprocess.file = WebKit2/WebProcess.pro
20     SUBDIRS += webprocess
21     enable?(PLUGIN_PROCESS) {
22         pluginprocess.file = WebKit2/PluginProcess.pro
23         SUBDIRS += pluginprocess
24     }
25
26     enable?(SUID_SANDBOX_LINUX) {
27         sandboxprocess.file = WebKit2/SandboxProcess.pro
28         SUBDIRS += sandboxprocess
29     }
30 }
31
32 declarative.file = WebKit/qt/declarative/declarative.pro
33 declarative.makefile = Makefile.declarative
34 have?(QTQUICK): SUBDIRS += declarative
35
36 build?(webkit1) {
37     build?(tests) {
38         tests.file = tests.pri
39         SUBDIRS += tests
40     }
41
42     examples.file = WebKit/qt/examples/examples.pro
43     examples.CONFIG += no_default_target
44     examples.makefile = Makefile
45     SUBDIRS += examples
46 }