6313258d8958516ae2b9c0ca2e4d14930765869d
[WebKit-https.git] / Source / JavaScriptCore / Target.pri
1 # -------------------------------------------------------------------
2 # Target file for the JavaScriptSource library
3 #
4 # See 'Tools/qmake/README' for an overview of the build system
5 # -------------------------------------------------------------------
6
7 TEMPLATE = lib
8 TARGET = JavaScriptCore
9
10 include(JavaScriptCore.pri)
11
12 WEBKIT += wtf
13 QT += core
14 QT -= gui
15
16 CONFIG += staticlib
17
18 *-g++*:QMAKE_CXXFLAGS_RELEASE -= -O2
19 *-g++*:QMAKE_CXXFLAGS_RELEASE += -O3
20
21 # Rules when JIT enabled (not disabled)
22 !contains(DEFINES, ENABLE_JIT=0) {
23     linux*-g++*:greaterThan(QT_GCC_MAJOR_VERSION,3):greaterThan(QT_GCC_MINOR_VERSION,0) {
24         QMAKE_CXXFLAGS += -fno-stack-protector
25         QMAKE_CFLAGS += -fno-stack-protector
26     }
27 }
28
29 wince* {
30     SOURCES += $$QT_SOURCE_TREE/src/3rdparty/ce-compat/ce_time.c
31 }
32
33 include(yarr/yarr.pri)
34
35 INSTALLDEPS += all
36
37 SOURCES += \
38     API/JSBase.cpp \
39     API/JSCallbackConstructor.cpp \
40     API/JSCallbackFunction.cpp \
41     API/JSCallbackObject.cpp \
42     API/JSClassRef.cpp \
43     API/JSContextRef.cpp \
44     API/JSObjectRef.cpp \
45     API/JSStringRef.cpp \
46     API/JSValueRef.cpp \
47     API/OpaqueJSString.cpp \
48     assembler/ARMAssembler.cpp \
49     assembler/ARMv7Assembler.cpp \
50     assembler/MacroAssemblerARM.cpp \
51     assembler/MacroAssemblerSH4.cpp \
52     bytecode/CallLinkInfo.cpp \
53     bytecode/CallLinkStatus.cpp \
54     bytecode/CodeBlock.cpp \
55     bytecode/DFGExitProfile.cpp \
56     bytecode/ExecutionCounter.cpp \
57     bytecode/GetByIdStatus.cpp \
58     bytecode/JumpTable.cpp \
59     bytecode/LazyOperandValueProfile.cpp \
60     bytecode/MethodCallLinkInfo.cpp \
61     bytecode/MethodCallLinkStatus.cpp \
62     bytecode/MethodOfGettingAValueProfile.cpp \
63     bytecode/Opcode.cpp \
64     bytecode/PolymorphicPutByIdList.cpp \
65     bytecode/PredictedType.cpp \
66     bytecode/PutByIdStatus.cpp \
67     bytecode/SamplingTool.cpp \
68     bytecode/StructureStubInfo.cpp \
69     bytecompiler/BytecodeGenerator.cpp \
70     bytecompiler/NodesCodegen.cpp \
71     heap/CopiedSpace.cpp \
72     heap/ConservativeRoots.cpp \
73     heap/DFGCodeBlocks.cpp \
74     heap/WeakSet.cpp \
75     heap/WeakHandleOwner.cpp \
76     heap/WeakBlock.cpp \
77     heap/HandleSet.cpp \
78     heap/HandleStack.cpp \
79     heap/BlockAllocator.cpp \
80     heap/Heap.cpp \
81     heap/MachineStackMarker.cpp \
82     heap/MarkStack.cpp \
83     heap/MarkedAllocator.cpp \
84     heap/MarkedBlock.cpp \
85     heap/MarkedSpace.cpp \
86     heap/VTableSpectrum.cpp \
87     heap/WriteBarrierSupport.cpp \
88     debugger/DebuggerActivation.cpp \
89     debugger/DebuggerCallFrame.cpp \
90     debugger/Debugger.cpp \
91     dfg/DFGAbstractState.cpp \
92     dfg/DFGAssemblyHelpers.cpp \
93     dfg/DFGByteCodeParser.cpp \
94     dfg/DFGCapabilities.cpp \
95     dfg/DFGCFAPhase.cpp \
96     dfg/DFGCFGSimplificationPhase.cpp \
97     dfg/DFGConstantFoldingPhase.cpp \
98     dfg/DFGCorrectableJumpPoint.cpp \
99     dfg/DFGCSEPhase.cpp \
100     dfg/DFGDriver.cpp \
101     dfg/DFGFixupPhase.cpp \
102     dfg/DFGGraph.cpp \
103     dfg/DFGJITCompiler.cpp \
104     dfg/DFGNodeFlags.cpp \
105     dfg/DFGOperations.cpp \
106     dfg/DFGOSREntry.cpp \
107     dfg/DFGOSRExit.cpp \
108     dfg/DFGOSRExitCompiler.cpp \
109     dfg/DFGOSRExitCompiler64.cpp \
110     dfg/DFGOSRExitCompiler32_64.cpp \
111     dfg/DFGPhase.cpp \
112     dfg/DFGPredictionPropagationPhase.cpp \
113     dfg/DFGRedundantPhiEliminationPhase.cpp \
114     dfg/DFGRepatch.cpp \
115     dfg/DFGSpeculativeJIT.cpp \
116     dfg/DFGSpeculativeJIT32_64.cpp \
117     dfg/DFGSpeculativeJIT64.cpp \
118     dfg/DFGThunks.cpp \
119     dfg/DFGValidate.cpp \
120     dfg/DFGVirtualRegisterAllocationPhase.cpp \
121     interpreter/AbstractPC.cpp \
122     interpreter/CallFrame.cpp \
123     interpreter/Interpreter.cpp \
124     interpreter/RegisterFile.cpp \
125     jit/ExecutableAllocatorFixedVMPool.cpp \
126     jit/ExecutableAllocator.cpp \
127     jit/HostCallReturnValue.cpp \
128     jit/JITArithmetic.cpp \
129     jit/JITArithmetic32_64.cpp \
130     jit/JITCall.cpp \
131     jit/JITCall32_64.cpp \
132     jit/JIT.cpp \
133     jit/JITExceptions.cpp \
134     jit/JITOpcodes.cpp \
135     jit/JITOpcodes32_64.cpp \
136     jit/JITPropertyAccess.cpp \
137     jit/JITPropertyAccess32_64.cpp \
138     jit/JITStubs.cpp \
139     jit/ThunkGenerators.cpp \
140     parser/Lexer.cpp \
141     parser/Nodes.cpp \
142     parser/ParserArena.cpp \
143     parser/Parser.cpp \
144     parser/SourceProviderCache.cpp \
145     profiler/Profile.cpp \
146     profiler/ProfileGenerator.cpp \
147     profiler/ProfileNode.cpp \
148     profiler/Profiler.cpp \
149     runtime/ArgList.cpp \
150     runtime/Arguments.cpp \
151     runtime/ArrayConstructor.cpp \
152     runtime/ArrayPrototype.cpp \
153     runtime/BooleanConstructor.cpp \
154     runtime/BooleanObject.cpp \
155     runtime/BooleanPrototype.cpp \
156     runtime/CallData.cpp \
157     runtime/CommonIdentifiers.cpp \
158     runtime/Completion.cpp \
159     runtime/ConstructData.cpp \
160     runtime/DateConstructor.cpp \
161     runtime/DateConversion.cpp \
162     runtime/DateInstance.cpp \
163     runtime/DatePrototype.cpp \
164     runtime/ErrorConstructor.cpp \
165     runtime/Error.cpp \
166     runtime/ErrorInstance.cpp \
167     runtime/ErrorPrototype.cpp \
168     runtime/ExceptionHelpers.cpp \
169     runtime/Executable.cpp \
170     runtime/FunctionConstructor.cpp \
171     runtime/FunctionPrototype.cpp \
172     runtime/GCActivityCallback.cpp \
173     runtime/GetterSetter.cpp \
174     runtime/Options.cpp \
175     runtime/Identifier.cpp \
176     runtime/InitializeThreading.cpp \
177     runtime/InternalFunction.cpp \
178     runtime/JSActivation.cpp \
179     runtime/JSAPIValueWrapper.cpp \
180     runtime/JSArray.cpp \
181     runtime/JSCell.cpp \
182     runtime/JSDateMath.cpp \
183     runtime/JSFunction.cpp \
184     runtime/JSBoundFunction.cpp \
185     runtime/JSGlobalData.cpp \
186     runtime/JSGlobalObject.cpp \
187     runtime/JSGlobalObjectFunctions.cpp \
188     runtime/JSGlobalThis.cpp \
189     runtime/JSLock.cpp \
190     runtime/JSNotAnObject.cpp \
191     runtime/JSObject.cpp \
192     runtime/JSONObject.cpp \
193     runtime/JSPropertyNameIterator.cpp \
194     runtime/JSStaticScopeObject.cpp \
195     runtime/JSString.cpp \
196     runtime/JSStringJoiner.cpp \
197     runtime/JSValue.cpp \
198     runtime/JSVariableObject.cpp \
199     runtime/JSWrapperObject.cpp \
200     runtime/LiteralParser.cpp \
201     runtime/Lookup.cpp \
202     runtime/MathObject.cpp \
203     runtime/NativeErrorConstructor.cpp \
204     runtime/NativeErrorPrototype.cpp \
205     runtime/NumberConstructor.cpp \
206     runtime/NumberObject.cpp \
207     runtime/NumberPrototype.cpp \
208     runtime/ObjectConstructor.cpp \
209     runtime/ObjectPrototype.cpp \
210     runtime/Operations.cpp \
211     runtime/PropertyDescriptor.cpp \
212     runtime/PropertyNameArray.cpp \
213     runtime/PropertySlot.cpp \
214     runtime/RegExpConstructor.cpp \
215     runtime/RegExpCachedResult.cpp \
216     runtime/RegExpMatchesArray.cpp \
217     runtime/RegExp.cpp \
218     runtime/RegExpObject.cpp \
219     runtime/RegExpPrototype.cpp \
220     runtime/RegExpCache.cpp \
221     runtime/SamplingCounter.cpp \
222     runtime/ScopeChain.cpp \
223     runtime/SmallStrings.cpp \
224     runtime/StrictEvalActivation.cpp \
225     runtime/StringConstructor.cpp \
226     runtime/StringObject.cpp \
227     runtime/StringPrototype.cpp \
228     runtime/StringRecursionChecker.cpp \
229     runtime/StructureChain.cpp \
230     runtime/Structure.cpp \
231     runtime/TimeoutChecker.cpp \
232     runtime/UString.cpp \
233     tools/CodeProfile.cpp \
234     tools/CodeProfiling.cpp \
235     yarr/YarrJIT.cpp \
236
237 *sh4* {
238     QMAKE_CXXFLAGS += -mieee -w
239     QMAKE_CFLAGS   += -mieee -w
240 }
241
242 lessThan(QT_GCC_MAJOR_VERSION, 5) {
243     # GCC 4.5 and before
244     lessThan(QT_GCC_MINOR_VERSION, 6) {
245         # Disable C++0x mode in JSC for those who enabled it in their Qt's mkspec.
246         *-g++*:QMAKE_CXXFLAGS -= -std=c++0x -std=gnu++0x
247     }
248
249     # GCC 4.6 and after.
250     greaterThan(QT_GCC_MINOR_VERSION, 5) {
251         if (!contains(QMAKE_CXXFLAGS, -std=c++0x) && !contains(QMAKE_CXXFLAGS, -std=gnu++0x)) {
252             # We need to deactivate those warnings because some names conflicts with upcoming c++0x types (e.g.nullptr).
253             QMAKE_CFLAGS_WARN_ON += -Wno-c++0x-compat
254             QMAKE_CXXFLAGS_WARN_ON += -Wno-c++0x-compat
255             QMAKE_CFLAGS += -Wno-c++0x-compat
256             QMAKE_CXXFLAGS += -Wno-c++0x-compat
257         }
258     }
259 }