Hoist JSVALUE32_64 arithmetic implementations into a separate file.
[WebKit-https.git] / JavaScriptCore / JavaScriptCore.pro
1 # JavaScriptCore - qmake build info
2 CONFIG += building-libs
3 include($$PWD/../WebKit.pri)
4 include(JavaScriptCore.pri)
5
6 TEMPLATE = lib
7 CONFIG += staticlib
8 # Don't use JavaScriptCore as the target name. qmake would create a JavaScriptCore.vcproj for msvc
9 # which already exists as a directory
10 TARGET = $$JAVASCRIPTCORE_TARGET
11 DESTDIR = $$JAVASCRIPTCORE_DESTDIR
12 QT += core
13 QT -= gui
14
15 CONFIG += depend_includepath
16
17 contains(QT_CONFIG, embedded):CONFIG += embedded
18
19 CONFIG(QTDIR_build) {
20     # Make sure we compile both debug and release on mac when inside Qt.
21     # This line was extracted from qbase.pri instead of including the whole file
22     win32|mac:!macx-xcode:CONFIG += debug_and_release
23 } else {
24     CONFIG(debug, debug|release) {
25         OBJECTS_DIR = obj/debug
26     } else { # Release
27         OBJECTS_DIR = obj/release
28     }
29     # Make sure that build_all follows the build_all config in WebCore
30     mac:contains(QT_CONFIG, qt_framework):!CONFIG(webkit_no_framework):!build_pass:CONFIG += build_all
31 }
32
33 # WebCore adds these config only when in a standalone build.
34 # qbase.pri takes care of that when in a QTDIR_build
35 # Here we add the config for both cases since we don't include qbase.pri
36 contains(QT_CONFIG, reduce_exports):CONFIG += hide_symbols
37 unix:contains(QT_CONFIG, reduce_relocations):CONFIG += bsymbolic_functions
38
39 CONFIG(QTDIR_build) {
40     # Remove the following 2 lines if you want debug information in JavaScriptCore
41     CONFIG -= separate_debug_info
42     CONFIG += no_debug_info
43 }
44
45 # Pick up 3rdparty libraries from INCLUDE/LIB just like with MSVC
46 win32-g++ {
47     TMPPATH            = $$quote($$(INCLUDE))
48     QMAKE_INCDIR_POST += $$split(TMPPATH,";")
49     TMPPATH            = $$quote($$(LIB))
50     QMAKE_LIBDIR_POST += $$split(TMPPATH,";")
51 }
52
53 *-g++*:QMAKE_CXXFLAGS_RELEASE -= -O2
54 *-g++*:QMAKE_CXXFLAGS_RELEASE += -O3
55
56 # Rules when JIT enabled (not disabled)
57 !contains(DEFINES, ENABLE_JIT=0) {
58     linux*-g++*:greaterThan(QT_GCC_MAJOR_VERSION,3):greaterThan(QT_GCC_MINOR_VERSION,0) {
59         QMAKE_CXXFLAGS += -fno-stack-protector
60         QMAKE_CFLAGS += -fno-stack-protector
61     }
62 }
63
64 wince* {
65     SOURCES += $$QT_SOURCE_TREE/src/3rdparty/ce-compat/ce_time.c
66 }
67
68 include(pcre/pcre.pri)
69
70 SOURCES += \
71     API/JSBase.cpp \
72     API/JSCallbackConstructor.cpp \
73     API/JSCallbackFunction.cpp \
74     API/JSCallbackObject.cpp \
75     API/JSClassRef.cpp \
76     API/JSContextRef.cpp \
77     API/JSObjectRef.cpp \
78     API/JSStringRef.cpp \
79     API/JSValueRef.cpp \
80     API/OpaqueJSString.cpp \
81     assembler/ARMAssembler.cpp \
82     assembler/MacroAssemblerARM.cpp \
83     bytecode/CodeBlock.cpp \
84     bytecode/JumpTable.cpp \
85     bytecode/Opcode.cpp \
86     bytecode/SamplingTool.cpp \
87     bytecode/StructureStubInfo.cpp \
88     bytecompiler/BytecodeGenerator.cpp \
89     bytecompiler/NodesCodegen.cpp \
90     debugger/DebuggerActivation.cpp \
91     debugger/DebuggerCallFrame.cpp \
92     debugger/Debugger.cpp \
93     interpreter/CallFrame.cpp \
94     interpreter/Interpreter.cpp \
95     interpreter/RegisterFile.cpp \
96     jit/ExecutableAllocatorFixedVMPool.cpp \
97     jit/ExecutableAllocatorPosix.cpp \
98     jit/ExecutableAllocatorSymbian.cpp \
99     jit/ExecutableAllocatorWin.cpp \
100     jit/ExecutableAllocator.cpp \
101     jit/JITArithmetic.cpp \
102     jit/JITArithmetic32_64.cpp \
103     jit/JITCall.cpp \
104     jit/JIT.cpp \
105     jit/JITOpcodes.cpp \
106     jit/JITPropertyAccess.cpp \
107     jit/JITPropertyAccess32_64.cpp \
108     jit/JITStubs.cpp \
109     jit/ThunkGenerators.cpp \
110     parser/Lexer.cpp \
111     parser/Nodes.cpp \
112     parser/ParserArena.cpp \
113     parser/Parser.cpp \
114     profiler/Profile.cpp \
115     profiler/ProfileGenerator.cpp \
116     profiler/ProfileNode.cpp \
117     profiler/Profiler.cpp \
118     runtime/ArgList.cpp \
119     runtime/Arguments.cpp \
120     runtime/ArrayConstructor.cpp \
121     runtime/ArrayPrototype.cpp \
122     runtime/BooleanConstructor.cpp \
123     runtime/BooleanObject.cpp \
124     runtime/BooleanPrototype.cpp \
125     runtime/CallData.cpp \
126     runtime/Collector.cpp \
127     runtime/CommonIdentifiers.cpp \
128     runtime/Completion.cpp \
129     runtime/ConstructData.cpp \
130     runtime/DateConstructor.cpp \
131     runtime/DateConversion.cpp \
132     runtime/DateInstance.cpp \
133     runtime/DatePrototype.cpp \
134     runtime/ErrorConstructor.cpp \
135     runtime/Error.cpp \
136     runtime/ErrorInstance.cpp \
137     runtime/ErrorPrototype.cpp \
138     runtime/ExceptionHelpers.cpp \
139     runtime/Executable.cpp \
140     runtime/FunctionConstructor.cpp \
141     runtime/FunctionPrototype.cpp \
142     runtime/GetterSetter.cpp \
143     runtime/GlobalEvalFunction.cpp \
144     runtime/Identifier.cpp \
145     runtime/InitializeThreading.cpp \
146     runtime/InternalFunction.cpp \
147     runtime/JSActivation.cpp \
148     runtime/JSAPIValueWrapper.cpp \
149     runtime/JSArray.cpp \
150     runtime/JSByteArray.cpp \
151     runtime/JSCell.cpp \
152     runtime/JSFunction.cpp \
153     runtime/JSGlobalData.cpp \
154     runtime/JSGlobalObject.cpp \
155     runtime/JSGlobalObjectFunctions.cpp \
156     runtime/JSImmediate.cpp \
157     runtime/JSLock.cpp \
158     runtime/JSNotAnObject.cpp \
159     runtime/JSNumberCell.cpp \
160     runtime/JSObject.cpp \
161     runtime/JSONObject.cpp \
162     runtime/JSPropertyNameIterator.cpp \
163     runtime/JSStaticScopeObject.cpp \
164     runtime/JSString.cpp \
165     runtime/JSValue.cpp \
166     runtime/JSVariableObject.cpp \
167     runtime/JSWrapperObject.cpp \
168     runtime/LiteralParser.cpp \
169     runtime/Lookup.cpp \
170     runtime/MarkStackPosix.cpp \
171     runtime/MarkStackSymbian.cpp \
172     runtime/MarkStackWin.cpp \
173     runtime/MarkStack.cpp \
174     runtime/MathObject.cpp \
175     runtime/NativeErrorConstructor.cpp \
176     runtime/NativeErrorPrototype.cpp \
177     runtime/NumberConstructor.cpp \
178     runtime/NumberObject.cpp \
179     runtime/NumberPrototype.cpp \
180     runtime/ObjectConstructor.cpp \
181     runtime/ObjectPrototype.cpp \
182     runtime/Operations.cpp \
183     runtime/PropertyDescriptor.cpp \
184     runtime/PropertyNameArray.cpp \
185     runtime/PropertySlot.cpp \
186     runtime/PrototypeFunction.cpp \
187     runtime/RegExpConstructor.cpp \
188     runtime/RegExp.cpp \
189     runtime/RegExpObject.cpp \
190     runtime/RegExpPrototype.cpp \
191     runtime/RopeImpl.cpp \
192     runtime/ScopeChain.cpp \
193     runtime/SmallStrings.cpp \
194     runtime/StringConstructor.cpp \
195     runtime/StringObject.cpp \
196     runtime/StringPrototype.cpp \
197     runtime/StructureChain.cpp \
198     runtime/Structure.cpp \
199     runtime/TimeoutChecker.cpp \
200     runtime/UString.cpp \
201     wtf/Assertions.cpp \
202     wtf/ByteArray.cpp \
203     wtf/CurrentTime.cpp \
204     wtf/DateMath.cpp \
205     wtf/dtoa.cpp \
206     wtf/FastMalloc.cpp \
207     wtf/HashTable.cpp \
208     wtf/MD5.cpp \
209     wtf/MainThread.cpp \
210     wtf/qt/MainThreadQt.cpp \
211     wtf/qt/StringQt.cpp \
212     wtf/qt/ThreadingQt.cpp \
213     wtf/RandomNumber.cpp \
214     wtf/RefCountedLeakCounter.cpp \
215     wtf/symbian/BlockAllocatorSymbian.cpp \
216     wtf/ThreadingNone.cpp \
217     wtf/Threading.cpp \
218     wtf/TypeTraits.cpp \
219     wtf/WTFThreadData.cpp \
220     wtf/text/AtomicString.cpp \
221     wtf/text/CString.cpp \
222     wtf/text/StringImpl.cpp \
223     wtf/text/WTFString.cpp \
224     wtf/unicode/CollatorDefault.cpp \
225     wtf/unicode/icu/CollatorICU.cpp \
226     wtf/unicode/UTF8.cpp \
227     yarr/RegexCompiler.cpp \
228     yarr/RegexInterpreter.cpp \
229     yarr/RegexJIT.cpp
230
231 # Generated files, simply list them for JavaScriptCore
232 SOURCES += \
233     $${JSC_GENERATED_SOURCES_DIR}/Grammar.cpp
234
235 !contains(DEFINES, USE_SYSTEM_MALLOC) {
236     SOURCES += wtf/TCSystemAlloc.cpp
237 }
238
239 # Disable C++0x mode in JSC for those who enabled it in their Qt's mkspec
240 *-g++*:QMAKE_CXXFLAGS -= -std=c++0x -std=gnu++0x