Top-Level:
[WebKit-https.git] / JavaScriptCore / JavaScriptCore.pri
1 # JavaScriptCore - Qt4 build info
2 VPATH += $$PWD
3
4 INCLUDEPATH += tmp
5 INCLUDEPATH += $$PWD $$PWD/parser $$PWD/bytecompiler $$PWD/debugger $$PWD/runtime $$PWD/wtf $$PWD/wtf/unicode $$PWD/interpreter $$PWD/jit $$PWD/profiler $$PWD/wrec $$PWD/API $$PWD/.. \
6                $$PWD/ForwardingHeaders $$PWD/bytecode $$PWD/assembler
7 DEFINES += BUILDING_QT__
8
9 isEmpty(GENERATED_SOURCES_DIR):GENERATED_SOURCES_DIR = tmp
10 GENERATED_SOURCES_DIR_SLASH = $$GENERATED_SOURCES_DIR/
11 win32-*: GENERATED_SOURCES_DIR_SLASH ~= s|/|\|
12 win32-g++: LIBS += -lwinmm
13
14
15 include(pcre/pcre.pri)
16
17 LUT_FILES += \
18     runtime/DatePrototype.cpp \
19     runtime/NumberConstructor.cpp \
20     runtime/StringPrototype.cpp \
21     runtime/ArrayPrototype.cpp \
22     runtime/MathObject.cpp \
23     runtime/RegExpConstructor.cpp \
24     runtime/RegExpObject.cpp
25
26 KEYWORDLUT_FILES += \
27     parser/Keywords.table
28
29 KJSBISON += \
30     parser/Grammar.y
31
32 SOURCES += \
33     wtf/Assertions.cpp \
34     wtf/HashTable.cpp \
35     wtf/MainThread.cpp \
36     wtf/RefCountedLeakCounter.cpp \
37     wtf/unicode/CollatorDefault.cpp \
38     wtf/unicode/icu/CollatorICU.cpp \
39     wtf/unicode/UTF8.cpp \
40     API/JSBase.cpp \
41     API/JSCallbackConstructor.cpp \
42     API/JSCallbackFunction.cpp \
43     API/JSCallbackObject.cpp \
44     API/JSClassRef.cpp \
45     API/JSContextRef.cpp \
46     API/JSObjectRef.cpp \
47     API/JSStringRef.cpp \
48     API/JSValueRef.cpp \
49     API/OpaqueJSString.cpp \
50     runtime/InitializeThreading.cpp \
51     runtime/JSGlobalData.cpp \
52     runtime/JSGlobalObject.cpp \
53     runtime/JSStaticScopeObject.cpp \
54     runtime/JSVariableObject.cpp \
55     runtime/JSActivation.cpp \
56     runtime/JSNotAnObject.cpp \
57     bytecode/CodeBlock.cpp \
58     jit/JIT.cpp \
59     bytecompiler/BytecodeGenerator.cpp \
60     runtime/ExceptionHelpers.cpp \
61     runtime/JSPropertyNameIterator.cpp \
62     interpreter/Interpreter.cpp \
63     bytecode/Opcode.cpp \
64     bytecode/SamplingTool.cpp \
65     interpreter/RegisterFile.cpp
66
67 # AllInOneFile.cpp helps gcc analize and optimize code
68 # Other compilers may be able to do this at link time
69 SOURCES += \
70     runtime/ArgList.cpp \
71     runtime/Arguments.cpp \
72     runtime/ArrayConstructor.cpp \
73     runtime/ArrayPrototype.cpp \
74     runtime/BooleanConstructor.cpp \
75     runtime/BooleanObject.cpp \
76     runtime/BooleanPrototype.cpp \
77     runtime/CallData.cpp \
78     runtime/Collector.cpp \
79     runtime/CommonIdentifiers.cpp \
80     runtime/ConstructData.cpp \
81     runtime/DateConstructor.cpp \
82     runtime/DateInstance.cpp \
83     runtime/DateMath.cpp \
84     runtime/DatePrototype.cpp \
85     debugger/Debugger.cpp \
86     debugger/DebuggerCallFrame.cpp \
87     wtf/dtoa.cpp \
88     runtime/Error.cpp \
89     runtime/ErrorConstructor.cpp \
90     runtime/ErrorInstance.cpp \
91     runtime/ErrorPrototype.cpp \
92     interpreter/CallFrame.cpp \
93     runtime/FunctionConstructor.cpp \
94     runtime/FunctionPrototype.cpp \
95     runtime/GetterSetter.cpp \
96     runtime/GlobalEvalFunction.cpp \
97     runtime/Identifier.cpp \
98     runtime/InternalFunction.cpp \
99     runtime/Completion.cpp \
100     runtime/JSArray.cpp \
101     runtime/JSCell.cpp \
102     runtime/JSFunction.cpp \
103     runtime/JSGlobalObjectFunctions.cpp \
104     runtime/JSImmediate.cpp \
105     runtime/JSLock.cpp \
106     runtime/JSNumberCell.cpp \
107     runtime/JSObject.cpp \
108     runtime/JSString.cpp \
109     runtime/JSValue.cpp \
110     runtime/JSWrapperObject.cpp \
111     parser/Lexer.cpp \
112     runtime/Lookup.cpp \
113     runtime/MathObject.cpp \
114     runtime/NativeErrorConstructor.cpp \
115     runtime/NativeErrorPrototype.cpp \
116     parser/Nodes.cpp \
117     runtime/NumberConstructor.cpp \
118     runtime/NumberObject.cpp \
119     runtime/NumberPrototype.cpp \
120     runtime/ObjectConstructor.cpp \
121     runtime/ObjectPrototype.cpp \
122     runtime/Operations.cpp \
123     parser/Parser.cpp \
124     runtime/PropertyNameArray.cpp \
125     runtime/PropertySlot.cpp \
126     runtime/PrototypeFunction.cpp \
127     runtime/RegExp.cpp \
128     runtime/RegExpConstructor.cpp \
129     runtime/RegExpObject.cpp \
130     runtime/RegExpPrototype.cpp \
131     runtime/ScopeChain.cpp \
132     runtime/SmallStrings.cpp \
133     runtime/StringConstructor.cpp \
134     runtime/StringObject.cpp \
135     runtime/StringPrototype.cpp \
136     runtime/Structure.cpp \
137     runtime/StructureChain.cpp \
138     runtime/UString.cpp \
139     profiler/HeavyProfile.cpp \
140     profiler/Profile.cpp \
141     profiler/ProfileGenerator.cpp \
142     profiler/ProfileNode.cpp \
143     profiler/Profiler.cpp \
144     profiler/TreeProfile.cpp \
145     wtf/FastMalloc.cpp \
146     wtf/ThreadingQt.cpp \
147     wtf/qt/MainThreadQt.cpp
148
149 # GENERATOR 1-A: LUT creator
150 lut.output = $$GENERATED_SOURCES_DIR/${QMAKE_FILE_BASE}.lut.h
151 lut.commands = perl $$PWD/create_hash_table ${QMAKE_FILE_NAME} -i > ${QMAKE_FILE_OUT}
152 lut.depend = ${QMAKE_FILE_NAME}
153 lut.input = LUT_FILES
154 lut.CONFIG += no_link
155 addExtraCompiler(lut)
156
157 # GENERATOR 1-B: particular LUT creator (for 1 file only)
158 keywordlut.output = $$GENERATED_SOURCES_DIR/Lexer.lut.h
159 keywordlut.commands = perl $$PWD/create_hash_table ${QMAKE_FILE_NAME} -i > ${QMAKE_FILE_OUT}
160 keywordlut.depend = ${QMAKE_FILE_NAME}
161 keywordlut.input = KEYWORDLUT_FILES
162 keywordlut.CONFIG += no_link
163 addExtraCompiler(keywordlut)
164
165 # GENERATOR 2: bison grammar
166 kjsbison.output = $$GENERATED_SOURCES_DIR/${QMAKE_FILE_BASE}.cpp
167 kjsbison.commands = bison -d -p kjsyy ${QMAKE_FILE_NAME} -o ${QMAKE_FILE_BASE}.tab.c && $(MOVE) ${QMAKE_FILE_BASE}.tab.c ${QMAKE_FILE_OUT} && $(MOVE) ${QMAKE_FILE_BASE}.tab.h $$GENERATED_SOURCES_DIR/${QMAKE_FILE_BASE}.h
168 kjsbison.depend = ${QMAKE_FILE_NAME}
169 kjsbison.input = KJSBISON
170 kjsbison.variable_out = GENERATED_SOURCES
171 kjsbison.dependency_type = TYPE_C
172 kjsbison.CONFIG = target_predeps
173 addExtraCompilerWithHeader(kjsbison)
174