2010-08-30 Alejandro G. Castro <alex@igalia.com>
[WebKit-https.git] / BugsSite / showdependencygraph.cgi
1 #!/usr/bin/env perl -wT
2 # -*- Mode: perl; indent-tabs-mode: nil -*-
3 #
4 # The contents of this file are subject to the Mozilla Public
5 # License Version 1.1 (the "License"); you may not use this file
6 # except in compliance with the License. You may obtain a copy of
7 # the License at http://www.mozilla.org/MPL/
8 #
9 # Software distributed under the License is distributed on an "AS
10 # IS" basis, WITHOUT WARRANTY OF ANY KIND, either express or
11 # implied. See the License for the specific language governing
12 # rights and limitations under the License.
13 #
14 # The Original Code is the Bugzilla Bug Tracking System.
15 #
16 # The Initial Developer of the Original Code is Netscape Communications
17 # Corporation. Portions created by Netscape are
18 # Copyright (C) 1998 Netscape Communications Corporation. All
19 # Rights Reserved.
20 #
21 # Contributor(s): Terry Weissman <terry@mozilla.org>
22 #                 Gervase Markham <gerv@gerv.net>
23
24 use strict;
25
26 use lib qw(. lib);
27
28 use File::Temp;
29
30 use Bugzilla;
31 use Bugzilla::Constants;
32 use Bugzilla::Util;
33 use Bugzilla::Error;
34 use Bugzilla::Bug;
35 use Bugzilla::Status;
36
37 Bugzilla->login();
38
39 my $cgi = Bugzilla->cgi;
40 my $template = Bugzilla->template;
41 my $vars = {};
42 # Connect to the shadow database if this installation is using one to improve
43 # performance.
44 my $dbh = Bugzilla->switch_to_shadow_db();
45
46 local our (%seen, %edgesdone, %bugtitles);
47
48 # CreateImagemap: This sub grabs a local filename as a parameter, reads the 
49 # dot-generated image map datafile residing in that file and turns it into
50 # an HTML map element. THIS SUB IS ONLY USED FOR LOCAL DOT INSTALLATIONS.
51 # The map datafile won't necessarily contain the bug summaries, so we'll
52 # pull possible HTML titles from the %bugtitles hash (filled elsewhere
53 # in the code)
54
55 # The dot mapdata lines have the following format (\nsummary is optional):
56 # rectangle (LEFTX,TOPY) (RIGHTX,BOTTOMY) URLBASE/show_bug.cgi?id=BUGNUM BUGNUM[\nSUMMARY]
57
58 sub CreateImagemap {
59     my $mapfilename = shift;
60     my $map = "<map name=\"imagemap\">\n";
61     my $default;
62
63     open MAP, "<$mapfilename";
64     while(my $line = <MAP>) {
65         if($line =~ /^default ([^ ]*)(.*)$/) {
66             $default = qq{<area alt="" shape="default" href="$1">\n};
67         }
68
69         if ($line =~ /^rectangle \((.*),(.*)\) \((.*),(.*)\) (http[^ ]*) (\d+)(\\n.*)?$/) {
70             my ($leftx, $rightx, $topy, $bottomy, $url, $bugid) = ($1, $3, $2, $4, $5, $6);
71
72             # Pick up bugid from the mapdata label field. Getting the title from
73             # bugtitle hash instead of mapdata allows us to get the summary even
74             # when showsummary is off, and also gives us status and resolution.
75             my $bugtitle = html_quote(clean_text($bugtitles{$bugid}));
76             $map .= qq{<area alt="bug $bugid" name="bug$bugid" shape="rect" } .
77                     qq{title="$bugtitle" href="$url" } .
78                     qq{coords="$leftx,$topy,$rightx,$bottomy">\n};
79         }
80     }
81     close MAP;
82
83     $map .= "$default</map>";
84     return $map;
85 }
86
87 sub AddLink {
88     my ($blocked, $dependson, $fh) = (@_);
89     my $key = "$blocked,$dependson";
90     if (!exists $edgesdone{$key}) {
91         $edgesdone{$key} = 1;
92         print $fh "$blocked -> $dependson\n";
93         $seen{$blocked} = 1;
94         $seen{$dependson} = 1;
95     }
96 }
97
98 # The list of valid directions. Some are not proposed in the dropdrown
99 # menu despite the fact that they are valid.
100 my @valid_rankdirs = ('LR', 'RL', 'TB', 'BT');
101
102 my $rankdir = $cgi->param('rankdir') || 'TB';
103 # Make sure the submitted 'rankdir' value is valid.
104 if (lsearch(\@valid_rankdirs, $rankdir) < 0) {
105     $rankdir = 'TB';
106 }
107
108 my $display = $cgi->param('display') || 'tree';
109 my $webdotdir = bz_locations()->{'webdotdir'};
110
111 if (!defined $cgi->param('id') && $display ne 'doall') {
112     ThrowCodeError("missing_bug_id");
113 }
114
115 my ($fh, $filename) = File::Temp::tempfile("XXXXXXXXXX",
116                                            SUFFIX => '.dot',
117                                            DIR => $webdotdir);
118 my $urlbase = Bugzilla->params->{'urlbase'};
119
120 print $fh "digraph G {";
121 print $fh qq{
122 graph [URL="${urlbase}query.cgi", rankdir=$rankdir]
123 node [URL="${urlbase}show_bug.cgi?id=\\N", style=filled, color=lightgrey]
124 };
125
126 my %baselist;
127
128 if ($display eq 'doall') {
129     my $dependencies = $dbh->selectall_arrayref(
130                            "SELECT blocked, dependson FROM dependencies");
131
132     foreach my $dependency (@$dependencies) {
133         my ($blocked, $dependson) = @$dependency;
134         AddLink($blocked, $dependson, $fh);
135     }
136 } else {
137     foreach my $i (split('[\s,]+', $cgi->param('id'))) {
138         ValidateBugID($i);
139         $baselist{$i} = 1;
140     }
141
142     my @stack = keys(%baselist);
143
144     if ($display eq 'web') {
145         my $sth = $dbh->prepare(q{SELECT blocked, dependson
146                                     FROM dependencies
147                                    WHERE blocked = ? OR dependson = ?});
148
149         foreach my $id (@stack) {
150             my $dependencies = $dbh->selectall_arrayref($sth, undef, ($id, $id));
151             foreach my $dependency (@$dependencies) {
152                 my ($blocked, $dependson) = @$dependency;
153                 if ($blocked != $id && !exists $seen{$blocked}) {
154                     push @stack, $blocked;
155                 }
156                 if ($dependson != $id && !exists $seen{$dependson}) {
157                     push @stack, $dependson;
158                 }
159                 AddLink($blocked, $dependson, $fh);
160             }
161         }
162     }
163     # This is the default: a tree instead of a spider web.
164     else {
165         my @blocker_stack = @stack;
166         foreach my $id (@blocker_stack) {
167             my $blocker_ids = Bugzilla::Bug::EmitDependList('blocked', 'dependson', $id);
168             foreach my $blocker_id (@$blocker_ids) {
169                 push(@blocker_stack, $blocker_id) unless $seen{$blocker_id};
170                 AddLink($id, $blocker_id, $fh);
171             }
172         }
173         my @dependent_stack = @stack;
174         foreach my $id (@dependent_stack) {
175             my $dep_bug_ids = Bugzilla::Bug::EmitDependList('dependson', 'blocked', $id);
176             foreach my $dep_bug_id (@$dep_bug_ids) {
177                 push(@dependent_stack, $dep_bug_id) unless $seen{$dep_bug_id};
178                 AddLink($dep_bug_id, $id, $fh);
179             }
180         }
181     }
182
183     foreach my $k (keys(%baselist)) {
184         $seen{$k} = 1;
185     }
186 }
187
188 my $sth = $dbh->prepare(
189               q{SELECT bug_status, resolution, short_desc
190                   FROM bugs
191                  WHERE bugs.bug_id = ?});
192 foreach my $k (keys(%seen)) {
193     # Retrieve bug information from the database
194     my ($stat, $resolution, $summary) = $dbh->selectrow_array($sth, undef, $k);
195     $stat ||= 'NEW';
196     $resolution ||= '';
197     $summary ||= '';
198
199     # Resolution and summary are shown only if user can see the bug
200     if (!Bugzilla->user->can_see_bug($k)) {
201         $resolution = $summary = '';
202     }
203
204     $vars->{'short_desc'} = $summary if ($k eq $cgi->param('id'));
205
206     my @params;
207
208     if ($summary ne "" && $cgi->param('showsummary')) {
209         $summary =~ s/([\\\"])/\\$1/g;
210         push(@params, qq{label="$k\\n$summary"});
211     }
212
213     if (exists $baselist{$k}) {
214         push(@params, "shape=box");
215     }
216
217     if (is_open_state($stat)) {
218         push(@params, "color=green");
219     }
220
221     if (@params) {
222         print $fh "$k [" . join(',', @params) . "]\n";
223     } else {
224         print $fh "$k\n";
225     }
226
227     # Push the bug tooltip texts into a global hash so that 
228     # CreateImagemap sub (used with local dot installations) can
229     # use them later on.
230     $bugtitles{$k} = trim("$stat $resolution");
231
232     # Show the bug summary in tooltips only if not shown on 
233     # the graph and it is non-empty (the user can see the bug)
234     if (!$cgi->param('showsummary') && $summary ne "") {
235         $bugtitles{$k} .= " - $summary";
236     }
237 }
238
239
240 print $fh "}\n";
241 close $fh;
242
243 chmod 0777, $filename;
244
245 my $webdotbase = Bugzilla->params->{'webdotbase'};
246
247 if ($webdotbase =~ /^https?:/) {
248      # Remote dot server. We don't hardcode 'urlbase' here in case
249      # 'sslbase' is in use.
250      $webdotbase =~ s/%([a-z]*)%/Bugzilla->params->{$1}/eg;
251      my $url = $webdotbase . $filename;
252      $vars->{'image_url'} = $url . ".gif";
253      $vars->{'map_url'} = $url . ".map";
254 } else {
255     # Local dot installation
256
257     # First, generate the png image file from the .dot source
258
259     my ($pngfh, $pngfilename) = File::Temp::tempfile("XXXXXXXXXX",
260                                                      SUFFIX => '.png',
261                                                      DIR => $webdotdir);
262     binmode $pngfh;
263     open(DOT, "\"$webdotbase\" -Tpng $filename|");
264     binmode DOT;
265     print $pngfh $_ while <DOT>;
266     close DOT;
267     close $pngfh;
268     
269     # On Windows $pngfilename will contain \ instead of /
270     $pngfilename =~ s|\\|/|g if $^O eq 'MSWin32';
271
272     # Under mod_perl, pngfilename will have an absolute path, and we
273     # need to make that into a relative path.
274     my $cgi_root = bz_locations()->{cgi_path};
275     $pngfilename =~ s#^\Q$cgi_root\E/?##;
276     
277     $vars->{'image_url'} = $pngfilename;
278
279     # Then, generate a imagemap datafile that contains the corner data
280     # for drawn bug objects. Pass it on to CreateImagemap that
281     # turns this monster into html.
282
283     my ($mapfh, $mapfilename) = File::Temp::tempfile("XXXXXXXXXX",
284                                                      SUFFIX => '.map',
285                                                      DIR => $webdotdir);
286     binmode $mapfh;
287     open(DOT, "\"$webdotbase\" -Tismap $filename|");
288     binmode DOT;
289     print $mapfh $_ while <DOT>;
290     close DOT;
291     close $mapfh;
292     $vars->{'image_map'} = CreateImagemap($mapfilename);
293 }
294
295 # Cleanup any old .dot files created from previous runs.
296 my $since = time() - 24 * 60 * 60;
297 # Can't use glob, since even calling that fails taint checks for perl < 5.6
298 opendir(DIR, $webdotdir);
299 my @files = grep { /\.dot$|\.png$|\.map$/ && -f "$webdotdir/$_" } readdir(DIR);
300 closedir DIR;
301 foreach my $f (@files)
302 {
303     $f = "$webdotdir/$f";
304     # Here we are deleting all old files. All entries are from the
305     # $webdot directory. Since we're deleting the file (not following
306     # symlinks), this can't escape to delete anything it shouldn't
307     # (unless someone moves the location of $webdotdir, of course)
308     trick_taint($f);
309     if (file_mod_time($f) < $since) {
310         unlink $f;
311     }
312 }
313
314 # Make sure we only include valid integers (protects us from XSS attacks).
315 my @bugs = grep(detaint_natural($_), split(/[\s,]+/, $cgi->param('id')));
316 $vars->{'bug_id'} = join(', ', @bugs);
317 $vars->{'multiple_bugs'} = ($cgi->param('id') =~ /[ ,]/);
318 $vars->{'display'} = $display;
319 $vars->{'rankdir'} = $rankdir;
320 $vars->{'showsummary'} = $cgi->param('showsummary');
321
322 # Generate and return the UI (HTML page) from the appropriate template.
323 print $cgi->header();
324 $template->process("bug/dependency-graph.html.tmpl", $vars)
325   || ThrowTemplateError($template->error());