Merged BugsSite to Bugzilla-3.0.3
[WebKit-https.git] / BugsSite / config.cgi
1 #!/usr/bin/perl -wT
2 # -*- Mode: perl; indent-tabs-mode: nil -*-
3 #
4 # The contents of this file are subject to the Mozilla Public
5 # License Version 1.1 (the "License"); you may not use this file
6 # except in compliance with the License. You may obtain a copy of
7 # the License at http://www.mozilla.org/MPL/
8 #
9 # Software distributed under the License is distributed on an "AS
10 # IS" basis, WITHOUT WARRANTY OF ANY KIND, either express or
11 # implied. See the License for the specific language governing
12 # rights and limitations under the License.
13 #
14 # The Original Code is the Bugzilla Bug Tracking System.
15 #
16 # The Initial Developer of the Original Code is Netscape Communications
17 # Corporation. Portions created by Netscape are
18 # Copyright (C) 1998 Netscape Communications Corporation. All
19 # Rights Reserved.
20 #
21 # Contributor(s): Terry Weissman <terry@mozilla.org>
22 #                 Myk Melez <myk@mozilla.org>
23
24 ################################################################################
25 # Script Initialization
26 ################################################################################
27
28 # Make it harder for us to do dangerous things in Perl.
29 use strict;
30
31 use lib qw(.);
32
33 use Bugzilla;
34 use Bugzilla::Constants;
35 use Bugzilla::Error;
36 use Bugzilla::Keyword;
37 use Bugzilla::Bug;
38 use Bugzilla::Field;
39
40 my $user = Bugzilla->login(LOGIN_OPTIONAL);
41 my $cgi  = Bugzilla->cgi;
42
43 # If the 'requirelogin' parameter is on and the user is not
44 # authenticated, return empty fields.
45 if (Bugzilla->params->{'requirelogin'} && !$user->id) {
46     display_data();
47 }
48
49 # Pass a bunch of Bugzilla configuration to the templates.
50 my $vars = {};
51 $vars->{'priority'}  = get_legal_field_values('priority');
52 $vars->{'severity'}  = get_legal_field_values('bug_severity');
53 $vars->{'platform'}  = get_legal_field_values('rep_platform');
54 $vars->{'op_sys'}    = get_legal_field_values('op_sys');
55 $vars->{'keyword'}    = [map($_->name, Bugzilla::Keyword->get_all)];
56 $vars->{'resolution'} = get_legal_field_values('resolution');
57 $vars->{'status'}    = get_legal_field_values('bug_status');
58 $vars->{'custom_fields'} =
59   [Bugzilla->get_fields({custom => 1, obsolete => 0, type => FIELD_TYPE_SINGLE_SELECT})];
60
61 # Include a list of product objects.
62 if ($cgi->param('product')) {
63     my @products = $cgi->param('product');
64     foreach my $product_name (@products) {
65         # We don't use check_product because config.cgi outputs mostly
66         # in XML and JS and we don't want to display an HTML error
67         # instead of that.
68         my $product = new Bugzilla::Product({ name => $product_name });
69         if ($product && $user->can_see_product($product->name)) {
70             push (@{$vars->{'products'}}, $product);
71         }
72     }
73 } else {
74     $vars->{'products'} = $user->get_selectable_products;
75 }
76
77 # Create separate lists of open versus resolved statuses.  This should really
78 # be made part of the configuration.
79 my @open_status;
80 my @closed_status;
81 foreach my $status (@{$vars->{'status'}}) {
82     is_open_state($status) ? push(@open_status, $status) 
83                            : push(@closed_status, $status);
84 }
85 $vars->{'open_status'} = \@open_status;
86 $vars->{'closed_status'} = \@closed_status;
87
88 # Generate a list of fields that can be queried.
89 $vars->{'field'} = [Bugzilla->dbh->bz_get_field_defs()];
90
91 display_data($vars);
92
93
94 sub display_data {
95     my $vars = shift;
96
97     my $cgi      = Bugzilla->cgi;
98     my $template = Bugzilla->template;
99
100     # Determine how the user would like to receive the output; 
101     # default is JavaScript.
102     my $format = $template->get_format("config", scalar($cgi->param('format')),
103                                        scalar($cgi->param('ctype')) || "js");
104
105     # Return HTTP headers.
106     print "Content-Type: $format->{'ctype'}\n\n";
107
108     # Generate the configuration file and return it to the user.
109     $template->process($format->{'template'}, $vars)
110       || ThrowTemplateError($template->error());
111     exit;
112 }